(VBScript) HTTPS Upload File to Web Server

Uploads a file to a web server using HTTPS.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The ContentType, HttpVerb, and Path properties should
'  always be explicitly set.
set req = CreateObject("Chilkat_9_5_0.HttpRequest")
req.HttpVerb = "POST"
req.Path = "/receiveMyUpload.aspx"
req.ContentType = "multipart/form-data"

success = req.AddStringForUpload("fileA","fileA.txt","This is the contents of file A","utf-8")
success = req.AddFileForUpload("starfish.jpg","qa_data/jpg/starfish.jpg")
If (success <> 1) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

set http = CreateObject("Chilkat_9_5_0.Http")

'  ----------------------------------------------------------------------------
'  IMPORTANT:
'  HTTP uploads require a counterpart implementation on the server, written in any desired language
'  such as C#, Classic ASP, PHP, etc., which consumes the upload being sent.
'  See: ASP.NET Receive Upload
'  ----------------------------------------------------------------------------

'  Do the upload.
useSslTls = 1
' resp is a Chilkat_9_5_0.HttpResponse
Set resp = http.SynchronousRequest("www.example.com",443,useSslTls,req)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("response status code = " & resp.StatusCode)
outFile.WriteLine("response body:")
outFile.WriteLine(resp.BodyStr)


outFile.Close