VBScript

Get XOAUTH2 Access Token from Google OAuth 2.0 Authorization Server

See more HTTP Examples

Obtains an OAUTH2 access token from the Google OAuth 2.0 Authorization Server. This is for Server to server applications using Google API's that need an access token. See https://developers.google.com/accounts/docs/OAuth2ServiceAccount VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' --------------------------------------------------------------------------------
' For a step-by-step guide for setting up your Google Workspace service account,
' see Setup Google Workspace Account for Sending SMTP GMail from a Service Account
' --------------------------------------------------------------------------------
' Begin by loading your Google service account key (.p12)
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("c:/someDirectory/keys/chilkat25-cbd7b42afbd8.p12","notasecret")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' The ISS is your service account email address ending in gserviceaccount.com.
iss = "chilkatsvc@chilkat25.iam.gserviceaccount.com"

' The scope is always the following string:
scope = "https://mail.google.com/"

' The sub is your company email address
oauth_sub = "bob@yourcompany.com"

' The access token is valid for this number of seconds.
numSec = 3600

accessToken = http.G_SvcOauthAccessToken(iss,scope,oauth_sub,numSec,cert)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
Else
    outFile.WriteLine("access token: " & accessToken)
End If

' The access token allows us to send unlimited emails while it's valid. Once it expires, we must obtain and use a new one.

outFile.Close