(VBScript) Send XMLHttpRequest and Get Response

Demonstrates how to send an HTTP XML request and retrieve the response.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' The XML sent in the body of the request is application
' specified -- it should contain whatever the server-side
' application is expecting..
xmlStr = "<?xml version=""1.0"" encoding=""UTF-8""?><appXml><something>123</something></appXml>"

' The PostXml method may be called to send the XMLHttpRequest
' using the "POST" HTTP method (also known as "verb").
urlEndpoint = "http://www.chilkatsoft.com/xmlEcho.asp"
xmlCharset = "utf-8"

' resp is a Chilkat.HttpResponse
Set resp = http.PostXml(urlEndpoint,xmlStr,xmlCharset)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' The raw HTTP request sent by the above call is:

' POST /xmlEcho.asp HTTP/1.1
' Content-Type: text/xml
' Host: www.chilkatsoft.com
' Accept: */*
' Accept-Charset: ISO-8859-1,utf-8;q=0.7,*; q=0.7
' Accept-Language: en-us,en;q=0.5
' Accept-Encoding: gzip
' Content-Length: 81
' 
' <?xml version="1.0" encoding="UTF-8"?><appXml><something>123</something></appXml>

' Examine the Body of the HTTP response
' This would be the XML response sent by the server.
outFile.WriteLine(resp.BodyStr)


outFile.Close