VBScript

WebDAV PROPFIND

See more HTTP Examples

Demonstrates how to send a WebDAV PROPFIND HTTP request. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set req = CreateObject("Chilkat.HttpRequest")
set http = CreateObject("Chilkat.Http")

' The PROPFIND request to be sent will look similar to this:
' This is from RFC 4918 at http://tools.ietf.org/html/rfc4918#section-9.1.3

'      PROPFIND /file HTTP/1.1
'      Host: www.example.com
'      Content-type: application/xml; charset="utf-8"
'      Content-Length: xxxx
' 
'      <?xml version="1.0" encoding="utf-8" ?>
'      <D:propfind xmlns:D="DAV:">
'        <D:prop xmlns:R="http://ns.example.com/boxschema/">
'          <R:bigbox/>
'          <R:author/>
'          <R:DingALing/>
'          <R:Random/>
'        </D:prop>
'      </D:propfind>

' Build the HTTP request object. 

' The HTTP verb should be "PROPFIND"
req.HttpVerb = "PROPFIND"

' The Content-Type should be "application/xml", and
' the charset attribute in the Content-Type header should
' be utf-8:
req.ContentType = "application/xml"
req.Charset = "utf-8"
req.SendCharset = 1

' Load the request body with the XML.  Your application 
' is free to construct the XML using any means desired.
' Once the XML is prepared, load it into the request body
' like this:
xmlBody = "This is the string that should contain the XML body..."
success = req.LoadBodyFromString(xmlBody,"utf-8")
If (success = 0) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

' For this example, pretend the WEBDAV endpoint is:
' https://webdav.chilkatstorage.com/

' Note: There is no actual "chilkatstorage.com" site.  
' This is only an example...

' The "path" part of this endpoint URL is simply "/".

' Send the request to the WebDAV endpoint using 
' the HttpSReq method:

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpSReq("webdav.chilkatstorage.com",443,1,req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Get the XML response:

responseXml = resp.BodyStr
outFile.WriteLine("XML Response: " & responseXml)

' Get the response status code, such as 207

statusCode = resp.StatusCode
outFile.WriteLine("StatusCode = " & statusCode)

outFile.Close