VBScript

Send HTTP POST using non-UTF8 such as Windows-1250

See more HTTP Examples

Demonstrates how to specify the character encoding (charset) to be used for the body of an HTTP POST. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

set req = CreateObject("Chilkat.HttpRequest")

' Load a JSON file containing strings with Polish chars.
set json = CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/json/has_polish_chars.json")
If (success = 0) Then
    outFile.WriteLine(json.LastErrorText)
    WScript.Quit
End If

' Add the request params expected by the server-side:
req.AddParam "tytul",json.StringOf("tytul")
req.AddParam "tresc",json.StringOf("tresc")

' Indicate we wish to explicitly send the charset attribute in the HTTP request header.
req.SendCharset = 1

' Send the POST
' You can send the POST to the URL below.  It will respond with the request body in quoted-printable format.
' Using quoted-printable, we can easily see the binary bytes for the accented chars.

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpReq("https://www.chilkatsoft.com/echoPost.cshtml",req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(http.LastHeader)
outFile.WriteLine(resp.BodyStr)

' Sample output:

' --------------------------------------------------
' POST /echoPost.cshtml HTTP/1.1
' Host: www.chilkatsoft.com
' Content-Type: application/x-www-form-urlencoded; charset=utf-8
' Content-Length: 79
' 
' <pre>tytul=3DPrzyk%C5%82ad&amp;tresc=3DPrzyk%C5%82ad
' %82oszenie</pre>
' --------------------------------------------------

' We can see by the %C5%82 that utf-8 was sent, because %C5%82 is the 2-byte representation of a particular Polish char.

' -----------------------
' However.. we can change the charset used for the HTTP request by specifying the request object's charset.

req.SendCharset = 1
req.Charset = "windows-1250"
req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

success = http.HttpReq("https://www.chilkatsoft.com/echoPost.cshtml",req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(http.LastHeader)
outFile.WriteLine(resp.BodyStr)

' Sample output...
' You can see how the bytes used for the Polish chars are now 1-byte per char (i.e. using Windows-1250) 

' --------------------------------------------------
' POST /echoPost.cshtml HTTP/1.1
' Host: www.chilkatsoft.com
' Content-Type: application/x-www-form-urlencoded; charset=windows-1250
' Content-Length: 70
' 
' <pre>tytul=3DPrzyk%B3ad&amp;tresc=3DPrzyk%B3ad
' e</pre>
' --------------------------------------------------

outFile.Close