VBScript

HTTP Public Key Pinning

See more HTTP Examples

Demonstrates how to specify a TLS pinset that lists the pre-known valid and accepted TLS server certificate public keys. When a TLS pinset is specified, the Chilkat TLS client software will reject TLS connections (inside the TLS handshake) when the server provides a certificate having a public key not listed in the pinset. This makes it possible to reject the connection at the earliest possible time, before any information (such as the HTTP request) has been sent to the server. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set httpA = CreateObject("Chilkat.Http")

' To do public key pinning, the SPKI fingerprint would be obtained beforehand -- perhaps
' at design time, or possibly at the time of the 1st connection (where the SPKI fingerprint
' is persisted for future use).  Note:  "If the certificate or public key is added upon first
' encounter, you will be using key continuity. Key continuity can fail if the attacker has a 
' privileged position during the first first encounter." 
' See https://www.owasp.org/index.php/Certificate_and_Public_Key_Pinning
set sslCert = CreateObject("Chilkat.Cert")
success = httpA.GetServerCert("www.ssllabs.com",443,sslCert)
If (success = 0) Then
    outFile.WriteLine(httpA.LastErrorText)
    WScript.Quit
End If

' The GetSpkiFingerprint method returns the SPKI Fingerprint suitable for use in pinning.
outFile.WriteLine("SPKI Fingerprint: " & sslCert.GetSpkiFingerprint("sha256","base64"))

' ------------------------------------------------------------------------------------

set httpB = CreateObject("Chilkat.Http")

' Set the TlsPinSet.  The format of the TlsPinSet string is:
'  "hashAlg, encoding, fingerprint1, fingerprint2, ..."
httpB.TlsPinSet = "sha256, base64, zVYucUTcGEk/8/HHt9ifInCRXVAf+hbxTgRTYnCjYk8="

' Our object will refuse to communicate with any TLS server where the server's public key
' does not match a pin in the pinset.

' This should be OK (assuming the ssllabs.com server certificate has not changed since
' the time of writing this example).
html = httpB.QuickGetStr("https://www.ssllabs.com/")
If (httpB.LastMethodSuccess = 0) Then
    outFile.WriteLine(httpB.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.  The HTTP GET worked because the server's certificate had a matching public key.")

' This should NOT be OK because owasp.org's server certificate will not have a matching public key.
html = httpB.QuickGetStr("https://www.owasp.org/index.php/Certificate_and_Public_Key_Pinning")
If (httpB.LastMethodSuccess = 0) Then
    outFile.WriteLine("Good, this connection was rejected...")
Else
    outFile.WriteLine("This was not supposed to happen!")
End If


outFile.Close