VBScript

HTTP POST and Stream Response to File

See more REST Examples

Demonstrates how to send an HTTP POST and stream the response body directly to a file. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

set url = CreateObject("Chilkat.Url")
' This URL will emit a response that echos the query params (name and age)
success = url.ParseUrl("https://www.chilkatsoft.com/readPost.asp")

' Connect to the web server
bAutoReconnect = 1
success = rest.Connect(url.Host,url.Port,url.Ssl,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.AddQueryParam("name","John")
success = rest.AddQueryParam("age","33")

'  Send the HTTP POST.
success = rest.SendReqFormUrlEncoded("POST",url.Path)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Read the response header.
responseStatusCode = rest.ReadResponseHeader()
If (responseStatusCode < 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & responseStatusCode)

' We expect a 200 response status if the file data is coming.
' Otherwise, we'll get a string response body with an error message(or no response body).
If (responseStatusCode = 200) Then

    set bodyStream = CreateObject("Chilkat.Stream")

    ' The stream's sink will be a file.
    bodyStream.SinkFile = "qa_output/out.txt"

    ' Read the response body to the stream.  Given that we've
    ' set the stream's sink to a file, it will stream directly
    ' to the file.
    success = rest.ReadRespBodyStream(bodyStream,1)
    If (success <> 1) Then
        outFile.WriteLine(rest.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine("Successfully streamed the response to a file.")

Else
    errResponse = rest.ReadRespBodyString()
    If (rest.LastMethodSuccess <> 1) Then
        outFile.WriteLine(rest.LastErrorText)
    Else
        outFile.WriteLine(errResponse)
    End If

End If


outFile.Close