(VBScript) HTTP POST (Duplicate Simple HTML Form POST)

Demonstrates how to duplicate a simple HTML form POST.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' This example simulates this FORM:
' <form action="echoPost.asp" method="post">
' First name: <input type="text" name="firstName"><br />
' Last name: <input type="text" name="lastName"><br />
' <input type="submit" value="Submit">
' </form>
' The online FORM is found at this URL:
' https://www.chilkatsoft.com/simpleForm.html

' Build an HTTP POST Request:
req.HttpVerb = "POST"

' The FORM target is http://www.chilkatsoft.com/processPost.asp
' An easy way of filling out most of the HTTP request object
' is to call SetFromUrl:
req.SetFromUrl "https://www.chilkatsoft.com/echoPost.asp"

' Send form params using application/x-www-form-urlencoded
req.ContentType = "application/x-www-form-urlencoded"

' The only remaining task is to add the params to the 
' HTTP request object:
req.AddParam "firstName","Matt"
req.AddParam "lastName","Jones"

' Send the HTTP POST and get the response.
' The POST is being sent to chilkatsoft.com, on port 443 (using TLS)
domain = "chilkatsoft.com"
port = 443
tls = 1

' The HTTP POST is sent here:
' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest(domain,port,tls,req)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Display the HTML source of the page returned.
outFile.WriteLine(resp.BodyStr)

outFile.Close