VBScript

How to Access Parts of a multipart/related HTTP Response

See more HTTP Examples

Demonstrates how to access the parts of a multipart/related response. This example sends a ficticious multipart/related request, and handles a ficticious multipart/related response.

We send the following multipart/related request:

Content-Type: multipart/related; start-info="text/xml"; type="application/xop+xml"; boundary="----=_Part_0_1744155.1118953559416"
Content-Length: 3453
SOAPAction: "some-SOAP-action"

------=_Part_1_4558657.1118953559446
Content-Type: application/xop+xml; type="text/xml"; charset=utf-8

<soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
  <soap:Body>
    <Detail xmlns="http://example.org/mtom/data">
      <image>
        <xop:Include xmlns:xop="http://www.w3.org/2004/08/xop/include" href="cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org" />
      </image>
    </Detail>
  </soap:Body>
</soap:Envelope>

------=_Part_1_4558657.1118953559446
Content-Type: image/jpeg
Content-ID: <5aeaa450-17f0-4484-b845-a8480c363444@example.org>


... binary data ...

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

set soapXml = CreateObject("Chilkat.Xml")

' Build the following SOAP XML

' <soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
'   <soap:Body>
'     <Detail xmlns="http://example.org/mtom/data">
'       <image>
'         <xop:Include xmlns:xop="http://www.w3.org/2004/08/xop/include" href="cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org" />
'       </image>
'     </Detail>
'   </soap:Body>
' </soap:Envelope>

soapXml.Tag = "soap:Envelope"
success = soapXml.AddAttribute("xmlns:soap","http://schemas.xmlsoap.org/soap/envelope/")
success = soapXml.UpdateAttrAt("soap:Body|Detail",1,"xmlns","http://example.org/mtom/data")
success = soapXml.UpdateAttrAt("soap:Body|Detail|image|xop:Include",1,"xmlns:xop","http://www.w3.org/2004/08/xop/include")
success = soapXml.UpdateAttrAt("soap:Body|Detail|image|xop:Include",1,"href","cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org")

soapXml.EmitXmlDecl = 0
xmlBody = soapXml.GetXml()
outFile.WriteLine(xmlBody)

set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.Path = "/something/someTarget"

req.ContentType = "multipart/related; start-info=""text/xml""; type=""application/xop+xml"""
req.AddHeader "SOAPAction","some-SOAP-action"

success = req.AddStringForUpload2("","",xmlBody,"utf-8","application/xop+xml; type=""text/xml""; charset=utf-8")

' The bytes will be sent as binary (not base64 encoded).
success = req.AddFileForUpload2("","qa_data/jpg/starfish.jpg","image/jpeg")

' The JPEG data is the 2nd sub-part, and therefore is at index 1 (the first sub-part is at index 0)
success = req.AddSubHeader(1,"Content-ID","<5aeaa450-17f0-4484-b845-a8480c363444@example.org>")

http.FollowRedirects = 1

useTls = 1
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpSReq("www.example.org",443,useTls,req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Imagine the HTTP response is multipart related and is something like this:

' HTTP/1.1 200 OK
' Cache-Control: no-cache, no-store
' Pragma: no-cache
' Transfer-Encoding: chunked
' Content-Type: multipart/related; boundary=------------080001080500020607080905
' Expires: -1
' Server: Microsoft-IIS/10.0
' X-AspNet-Version: 4.0.30319
' X-Powered-By: ASP.NET
' Date: Wed, 19 Feb 2020 15:27:06 GMT
' 
' --------------080001080500020607080905
' Content-Type: application/xop+xml; charset=iso-8859-1
' Content-Id: RootPart
' Content-Transfer-Encoding: binary
' 
' <?xml version="1.0" encoding="iso-8859-1"?>
' <soapenv:Envelope xmlns:xcpt="...">
'   <soapenv:Header />
'   <soapenv:Body>
'     <xres:Transport profile="http://something.example.com/..." version="1.4">
'       <xres:TransportHeader>
' 	...
' 	...
'       </xres:TransportHeader>
'       <xres:TransportBody />
'     </xres:Transport>
'   </soapenv:Body>
' </soapenv:Envelope>
' --------------080001080500020607080905--

' To get the XML, load the full MIME of the response into a Chilkat MIME object.  Then get the body of the 1st sub-part.
set mime = CreateObject("Chilkat.Mime")
success = mime.LoadMime(resp.FullMime)

' Your code might verify that the Content-Type is indeed multipart/related.
outFile.WriteLine(mime.ContentType)
outFile.WriteLine("num parts = " & mime.NumParts)

' Assuming it is, and the number of sub-parts is > 0
If (mime.NumParts > 0) Then

    set part0 = CreateObject("Chilkat.Mime")
    success = mime.PartAt(0,part0)

    ' The Content-Type (in this ficticious example) should be "application/xop+xml"
    outFile.WriteLine("sub-part Content-Type: " & part0.ContentType)
    ' Now get the XML 
    subPartXmlBody = part0.GetBodyDecoded()
    outFile.WriteLine(subPartXmlBody)
End If


outFile.Close