VBScript

HTTP HEAD Request

See more HTTP Examples

Sends an HTTP HEAD request and gets the response.

Note: The response to an HTTP HEAD request is always just the response header. The reponse body is always 0 length (thus the reason it's called a "HEAD" request..)

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' If the URL uses "https://", then the connection will be TLS.
' Otherwise it will be TCP.

' A failure is when we don't get any response.  It could be a timeout, an inability to connect, etc.
' For example, a "404 Not Found" response is still a response, and thus deemed success in terms of the API..

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpNoBody("HEAD","https://example-code.com/",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Examine the response.
outFile.WriteLine("Status Code = " & resp.StatusCode)
outFile.WriteLine("Status Line = " & resp.StatusLine)
outFile.WriteLine("Status Text = " & resp.StatusText)
outFile.WriteLine("Full Response Header:")
outFile.WriteLine(resp.Header)
outFile.WriteLine("----")
numHeaderFields = resp.NumHeaderFields
outFile.WriteLine("Num Header Fields: " & numHeaderFields)

For i = 0 To numHeaderFields - 1
    outFile.WriteLine(resp.GetHeaderName(i) & ": " & resp.GetHeaderValue(i))
Next

outFile.Close