(VBScript) HTTP GET with Custom Header and OAuth2 Bearer Token

See more HTTP Examples

Demonstrate how to send a GET request with customer headers and an "Authorization: Bearer " header.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Setting the AuthToken property causes the "Authorization: Bearer <token>" header to be adeded.
http.AuthToken = "Just_the_access_token_here"

' Add one or more custom headers..
http.SetRequestHeader "X-Tenant-ID","value goes here"
http.SetRequestHeader "blah-blah-blah","value goes here"

url = "https://www.example.com/abc/123?x=something&y=someOtherThing"

' Send the GET request and get the response body in the StringBuilder object.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb(url,sb)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("response status code: " & http.LastStatus)
outFile.WriteLine("response body:")
outFile.WriteLine(sb.GetAsString())

' If the response contains JSON, you can load it into a Chilkat JSON object...
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.LoadSb(sb)
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

outFile.Close