(VBScript) HTTPS GET Request with Authorization Bearer Header

See more HTTP Examples

Demonstrates how to send an HTTPS GET request with an "Authorization: Bearer " header and get the text response (which could be JSON).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Setting the AuthToken property causes the "Authorization: Bearer <token>" header to be added to each request.
' Set AuthToken equal to your token without the keyword "Bearer".
http.AuthToken = "Your access token"

' Send the GET request and get the response text (assuming you know beforehand that the response will be text, such as JSON, XML, HTML, etc.)
responseText = http.QuickGetStr("https://www.example.com/something")
If (http.LastMethodSuccess = 0) Then
    ' This means something failed where you did not get an HTTP response.
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' If you get here, then you received an HTTP response where you can check the response status code, and the responseText will contain
' the response body.
outFile.WriteLine("Response status code = " & http.LastStatus)
If (http.LastStatus <> 200) Then
    ' Probably an error from the server.  Examine the HTTP response body.
    outFile.WriteLine(responseText)
    WScript.Quit
End If

' If you get here, the response status code was the expected value indicating success,
' if you know the response is JSON, you can load it into a Chilkat JSON object and continue ...
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 1
success = json.Load(responseText)
outFile.WriteLine(json.Emit())

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

' ...
' ...

outFile.Close