VBScript

Cancel HTTP Get Async Task if not Completed after a Max Time

See more HTTP Examples

Demonstrates how to wait a maximum amount of time for an asynchronous task to completed. If not completed in the allotted amount of time, the task is cancelled. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' Set some timeouts, in seconds:
http.ConnectTimeout = 15
' ReadTimeout specifies the max number of seconds that must elapse when no additional data is received before
' timing out.  For example, if a server sends a 300 byte response at the rate of 1 byte per second, then
' ReadTimeout would never cause a timeout because there is never a 15 second interval when nothing arrives.
http.ReadTimeout = 15

url = "https://your-url.com/something"
' task is a Chilkat.Task
Set task = http.QuickGetStrAsync(url)
success = task.Run()

' Wait a maximum of waitMaxMs for the task (i.e. the HTTP GET) to complete.
' The Wait method returns when the task has been canceled, aborted, or completed, or when the max allotted time has passed.
waitMaxMs = 20000
success = task.Wait(waitMaxMs)

' At this point, the GET may or may not have completed.  
' Rather than checking the Task status, we can call task.Cancel because
' if the Task is no longer running (because it already completed, was canceled or aborted), then the 
' call to Cancel is a NO-OP (meaning it does nothing and the Task's status is unaffected).
' Also, task.Cancel returns 1 if the task was in the "queued" or "running" state and was canceled or aborted. 
' The method returns 0 if the task has any other status.
wasCanceled = task.Cancel()
If (wasCanceled = 1) Then
    outFile.WriteLine("The HTTP GET took too long and was canceled.")
Else
    ' Find out what happened.
    If (task.StatusInt = 7) Then
        ' The task completed, which means the background thread's call to QuickGetStr completed
        ' with success or failure.  Find out which...
        If (task.TaskSuccess = 1) Then
            ' Get the string response for the call to QuickGetStr (which happened in Chilkat's background thread).
            responseStr = task.GetResultString()
            outFile.WriteLine(responseStr)
            outFile.WriteLine("HTTP GET successful!")
        Else
            outFile.WriteLine("HTTP GET failed prior to waitMaxMs...")
            outFile.WriteLine(task.ResultErrorText)
        End If

    Else
        ' The task must've been canceled or aborted by some other means..
        outFile.WriteLine("Task did not complete.  Final status: " & task.Status)
    End If

End If


outFile.Close