VBScript

Get the Server Certificate, Certificate Chain, and Root CA Certificate

See more HTTP Examples

Demonstrates how to get the HTTP server certificate, its certificate chain, and the root CA certificate. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' We're getting the SSL/TLS certificate, so make sure to connect to the SSL/TLS port (443).
set sslCert = CreateObject("Chilkat.Cert")
success = http.GetServerCert("apple.com",443,sslCert)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

set certChain = CreateObject("Chilkat.CertChain")
success = sslCert.BuildCertChain(certChain)
If (success = 0) Then
    outFile.WriteLine(sslCert.LastErrorText)
    WScript.Quit
End If

set cert = CreateObject("Chilkat.Cert")
i = 0
numCerts = certChain.NumCerts
Do While i < numCerts
    success = certChain.CertAt(i,cert)
    outFile.WriteLine("SubjectDN " & i & ": " & cert.SubjectDN)
    outFile.WriteLine("IssuerDN " & i & ": " & cert.IssuerDN)
    i = i + 1
Loop

' If the certificate chain reaches the root CA cert, then the last cert in the chain
' is the root CA cert.
If (certChain.ReachesRoot = 1) Then
    set caCert = CreateObject("Chilkat.Cert")
    success = certChain.CertAt(numCerts - 1,caCert)
    outFile.WriteLine("CA Root Cert: " & caCert.SubjectDN)
End If


outFile.Close