(VBScript) Adding Cookies to an HTTP Request

Demonstrates how to add one or more cookies to an HTTP request. For Chilkat HTTP methods that use an HTTP request object, such as SynchronousRequest or PostUrlEncoded, cookies are added by calling the AddHeader method on the request object. For Chilkat HTTP methods that do not use an HTTP request object, such as QuickGetStr, cookies are added by calling AddQuickHeader.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' The Cookie header field has this format:
' Cookie: name1=value1 [; name2=value2] ...

' Build an HTTP POST request:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.SetFromUrl "https://www.chilkatsoft.com/echoPost.asp"
req.HttpVerb = "POST"

req.AddParam "param1","value1"
req.AddParam "param2","value2"

' To add cookies to any HTTP request sent by a Chilkat HTTP method
' that uses an HTTP request object, add the cookies to the
' request object by calling AddHeader.  

' Add two cookies:
req.AddHeader "Cookie","user=""mary""; city=""Chicago"""

' Send the HTTP POST.  
' (The cookies are sent as part of the HTTP header.)

domain = "www.chilkatsoft.com"
port = 443
ssl = 1
' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Display the HTML body of the response.
If (resp.StatusCode = 200) Then
    ' Show the last HTTP request header sent, which should include
    ' our cookies...
    outFile.WriteLine(http.LastHeader)
Else
    outFile.WriteLine("HTTP Response Status = " & resp.StatusCode)
End If

outFile.WriteLine("---------------------")

' Some Chilkat HTTP methods do not use an HTTP request object. 
' For these methods, such as for QuickGetStr, cookies (or any HTTP request header) 
' are added by calling SetRequestHeader.  
http.SetRequestHeader "Cookie","user=""mary""; city=""Chicago"""

html = http.QuickGetStr("https://www.example.com/")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
Else
    ' Show the last HTTP request header sent, which should include
    ' our cookies...
    outFile.WriteLine(http.LastHeader)
End If


outFile.Close