(VBScript) Adding Cookies to an HTTP Request

Demonstrates how to add one or more cookies to an HTTP request. For Chilkat HTTP methods that use an HTTP request object, such as SynchronousRequest or PostUrlEncoded, cookies are added by calling the AddHeader method on the request object. For Chilkat HTTP methods that do not use an HTTP request object, such as QuickGetStr, cookies are added by calling AddQuickHeader.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set http = CreateObject("Chilkat_9_5_0.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

'  The Cookie header field has this format:
'  Cookie: name1=value1 [; name2=value2] ...

'  Build an HTTP POST request:
set request = CreateObject("Chilkat_9_5_0.HttpRequest")
request.SetFromUrl "http://www.chilkatsoft.com/echoPost.asp"
request.HttpVerb = "POST"

request.AddParam "param1","value1"
request.AddParam "param2","value2"

'  To add cookies to any HTTP request sent by a Chilkat HTTP method
'  that uses an HTTP request object, add the cookies to the
'  request object by calling AddHeader.

'  Add two cookies:
request.AddHeader "Cookie","user=""mary""; city=""Chicago"""

'  Send the HTTP POST.
'  (The cookies are sent as part of the HTTP header.)

domain = "www.chilkatsoft.com"
port = 80
ssl = 0
' response is a Chilkat_9_5_0.HttpResponse
Set response = http.SynchronousRequest(domain,port,ssl,request)
If (response Is Nothing ) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

'  Display the HTML body of the response.
If (response.StatusCode = 200) Then
    '  Show the last HTTP request header sent, which should include
    '  our cookies...
    outFile.WriteLine(http.LastHeader)
Else
    outFile.WriteLine("HTTP Response Status = " & response.StatusCode)
End If

outFile.WriteLine("---------------------")

'  Some Chilkat HTTP methods do not use an HTTP request object.
'  For these methods, such as for QuickGetStr, cookies (or any HTTP request header)
'  are added by calling AddQuickHeader.
success = http.AddQuickHeader("Cookie","user=""mary""; city=""Chicago""")

html = http.QuickGetStr("http://www.w3.org/")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
Else
    '  Show the last HTTP request header sent, which should include
    '  our cookies...
    outFile.WriteLine(http.LastHeader)
End If


outFile.Close