VBScript
hotelbeds.com REST API Authentication

Demonstrates how to calculate the X-Signature header and add to requests sent to api.test.hotelbeds.com.
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example duplicates the following CURL statement provided in the hotelbeds.com "Getting Started"
' developer documentation:

' #!/bin/bash 
' apiKey="yourApiKey"
' secret="yourSecret"
' curl -i \
'   -X GET \
'   -H 'Accept:application/json' \
'   -H 'Api-key:'$apiKey'' \
'   -H 'X-Signature:'$(echo -n ${apiKey}${secret}$(date +%s)|sha256sum|awk '{ print $1}')'' \
'   https://api.test.hotelbeds.com/hotel-api/1.0/status

' The "date + %s" command emits a UNIX date/time number such as 1605548842
' We need to concatenate the apiKey, secret, and current date/time in UNIX (numeric) time format.
set dt = CreateObject("Chilkat.CkDateTime")
success = dt.SetFromCurrentSystemTime()
' Get the UNIX time string in the GMT timezone.
bLocalTime = 0
unixTimeStr = dt.GetAsUnixTimeStr(bLocalTime)
outFile.WriteLine(unixTimeStr)

' Use your own API key and secret.  (These are not valid values)
apiKey = "227b20a2cb705e45f3b0a0944672dc07"
secret = "54dc7ba9e2"

set sb = CreateObject("Chilkat.StringBuilder")
success = sb.Append(apiKey)
success = sb.Append(secret)
success = sb.Append(unixTimeStr)

set crypt = CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "sha256"
crypt.EncodingMode = "hexlower"
signature = crypt.HashStringENC(sb.GetAsString())

outFile.WriteLine(signature)

set http = CreateObject("Chilkat.Http")

http.SetRequestHeader "Accept","application/json"
http.SetRequestHeader "Api-key",apiKey
http.SetRequestHeader "X-Signature",signature

jsonResponse = http.QuickGetStr("https://api.test.hotelbeds.com/hotel-api/1.0/status")
outFile.WriteLine(jsonResponse)
outFile.WriteLine(http.LastStatus)

' Sample output:  

' 1605549542
' 2146aefb36e7331b3b29aafd7638398ca22e689573224f1a71274d60bd201ec2
' {"auditData":{"timestamp":"2020-11-16 18:59:02.430"},"status":"OK"}
' 200

outFile.Close