VBScript

Calculate HRMC IRMark

See more XML Digital Signatures Examples

Demonstrates how to calculate an IRmark for an HMRC GovTalkMessage XML document.

Chilkat VBScript Downloads

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First build a sample (but incomplete) GovTalkMessage.
' You can replace this code with a call to LoadXml or LoadXmlFile..
' 
' Note: The online tool at https://tools.chilkat.io/xmlCreate.cshtml
' can be used to generate XML code that creates a given XML document.
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "GovTalkMessage"
success = xml.AddAttribute("xmlns","http://www.govtalk.gov.uk/CM/envelope")
success = xml.UpdateAttrAt("Body|Message",1,"xmlns","urn:g3.ge:dea:call:SendDocument:v1")
xml.UpdateChildContent "Body|Message","................"

' This is the XML created:
' <?xml version="1.0" encoding="utf-8" ?>
' <GovTalkMessage xmlns="http://www.govtalk.gov.uk/CM/envelope">
'     <Body>
'         <Message xmlns="urn:g3.ge:dea:call:SendDocument:v1">................</Message>
'     </Body>
' </GovTalkMessage>

outFile.WriteLine(xml.GetXml())

' Canonicalize the XML (using C14N)
set xdsig = CreateObject("Chilkat.XmlDSig")
withComments = 0
canonXml = xdsig.CanonicalizeXml(xml.GetXml(),"C14N",withComments)

' Return the base64 SHA-1 HASH of the canonical XML.
set crypt = CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "sha1"
crypt.EncodingMode = "base64"
irmark = crypt.HashStringENC(canonXml)

outFile.WriteLine("IRMark = " & irmark)

outFile.Close