VBScript

Google Vision Web Detection

Demonstrates how to use the Cloud Cloud Vision API for the Web Detection method.

The Google Cloud Vision "web detection" API call performs web detection analysis on an image. When you send an image to the Vision API with the "web detection" feature enabled, the API returns information about web entities (objects, logos, landmarks, etc.) that are visually similar to objects in the image and are found on the web.

It includes:

Entity Recognition: The API identifies entities (objects, landmarks, logos, etc.) present in the image and provides information about them. This can include labels, descriptions, and additional metadata.
Web Pages: For recognized entities, the API retrieves information about web pages that contain visually similar images or information related to the entities found in the image.
Matching Images: The API may return URLs of images found on the web that are visually similar to the objects in the image being analyzed.
Best Guess Label: The API may also provide a "best guess" label or description for the image based on its analysis of the web entities.
Related Web Entities: Additionally, the API may return related web entities or concepts that are semantically related to the recognized objects.

Overall, the web detection feature of the Google Cloud Vision API allows you to perform reverse image search-like functionality, identifying objects in an image and providing information about similar objects found on the web. This can be useful for tasks such as image classification, content moderation, and visual search applications.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' The following JSON is sent in the request body.

' {
'   "requests": [
'     {
'       "image": {
'         "source": {
'           "imageUri": "gs://visionapi-demo/ali.jpg"
'         }
'       },
'       "features": [
'         {
'           "maxResults": 10,
'           "type": "WEB_DETECTION"
'         }
'       ]
'     }
'   ]
' }

' The following code creates the JSON request body.
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("requests[0].image.source.imageUri","gs://visionapi-demo/ali.jpg")
success = json.UpdateInt("requests[0].features[0].maxResults",10)
success = json.UpdateString("requests[0].features[0].type","WEB_DETECTION")

json.EmitCompact = 0
outFile.WriteLine(json.Emit())

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","https://vision.googleapis.com/v1/images:annotate?key=your-api-key-here",json,"application/json",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

set jResp = CreateObject("Chilkat.JsonObject")
success = resp.GetBodyJson(jResp)
jResp.EmitCompact = 0

outFile.WriteLine("Response Body:")
outFile.WriteLine(jResp.Emit())

respStatusCode = resp.StatusCode
outFile.WriteLine("Response Status Code = " & respStatusCode)
If (respStatusCode >= 400) Then
    outFile.WriteLine("Response Header:")
    outFile.WriteLine(resp.Header)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If


outFile.Close