(VBScript) Google Photos Refresh Access Token

Demonstrates how to refresh a Google Access Token. Refreshing an oauth2 access token does not need to display an interactive browser like when originally getting the OAuth2 access token for the 1st time. Your application can do it automatically without user interaction.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Google Photos OAuth2 Access Token

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/googlePhotos.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load googlePhotos.json")
    WScript.Quit
End If

' The access token JSON looks like this:

' {
'   "access_token": "ya29.GlamBqWR6cp8lEfJMmTHVEua45912XLKoq4djyHl_Z3CEIzsPLIZkJSGie5oOrbaggy1rjJHn1zW5bjqSesGr5MEYIp9Hx-0CuvjVYf8srg2jeaDMwMACvzemp43",
'   "expires_in": 3600,
'   "refresh_token": "1/rl6k16nysDl9Bp1EhRH9F1WyRIoiSQAvko49Z4yY694MT5V1QXLj2ibNZGaRgek0",
'   "scope": "https://www.googleapis.com/auth/photoslibrary",
'   "token_type": "Bearer"
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.OAuth2")
set oauth2 = CreateObject("Chilkat.OAuth2")

oauth2.TokenEndpoint = "https://www.googleapis.com/oauth2/v4/token"

' Replace these with actual values.
oauth2.ClientId = "GOOGLE-CLIENT-ID"
oauth2.ClientSecret = "GOOGLE-CLIENT-SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' The response contains a new access token, but we must keep
' our existing refresh token for when we need to refresh again in the future.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

' Save the new JSON access token response to a file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJson = CreateObject("Chilkat.StringBuilder")
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/googlePhotos.json","utf-8",0)

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

outFile.Close