(VBScript) List all Pages of Files in Google Drive

Demonstrates how iterate over pages to list files in Google Drive.

See Google Drive Files list for more optional HTTP parameters.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 1

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' Google Drive scope.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.AccessToken = "GOOGLE-DRIVE-ACCESS-TOKEN"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

' Get 5 results per page for testing.  (The default page size is 100, with a max of 1000.
success = rest.AddQueryParam("pageSize","5")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")

' Send the request for the 1st page.
jsonResponse = rest.FullRequestNoBody("GET","/drive/v3/files")

pageNumber = 1

bContinueLoop = rest.LastMethodSuccess And (rest.ResponseStatusCode = 200)

Do While bContinueLoop = 1

    outFile.WriteLine("---- Page " & pageNumber & " ----")

    ' Iterate over each file in the response and show the name, id, and mimeType.
    success = json.Load(jsonResponse)

    ' See the sample JSON response at the bottom of this example.
    numFiles = json.SizeOfArray("files")
    i = 0
    Do While i < numFiles
        json.I = i
        outFile.WriteLine("name: " & json.StringOf("files[i].name"))
        outFile.WriteLine("id: " & json.StringOf("files[i].id"))
        outFile.WriteLine("mimeType: " & json.StringOf("files[i].mimeType"))
        outFile.WriteLine("-")
        i = i + 1
    Loop

    ' Get the next page of files.
    ' If the "nextPageToken" is present in the JSON response, then use it in the "pageToken" parameter
    ' for the next request.   If no "nextPageToken" was present, then this was the last page of files.
    pageToken = json.StringOf("nextPageToken")
    bContinueLoop = 0
    bHasMorePages = json.LastMethodSuccess
    If (bHasMorePages = 1) Then
        success = rest.ClearAllQueryParams()
        success = rest.AddQueryParam("pageSize","5")
        success = rest.AddQueryParam("pageToken",pageToken)
        jsonResponse = rest.FullRequestNoBody("GET","/drive/v3/files")
        bContinueLoop = rest.LastMethodSuccess And (rest.ResponseStatusCode = 200)
        pageNumber = pageNumber + 1
    End If

Loop

If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response JSON: " & jsonResponse)
    WScript.Quit
End If

' A successful JSON response looks like this:
' {
'  "kind": "drive#fileList",
'  "files": [
'    {
'      "kind": "drive#file",
'      "id": "0B53Q6OSTWYolenpjTEU4ekJlQUU",
'      "name": "test",
'      "mimeType": "application/vnd.google-apps.folder"
'    },
'    {
'      "kind": "drive#file",
'      "id": "0B53Q6OSTWYolRm4ycjZtdXhRaEE",
'      "name": "starfish4.jpg",
'      "mimeType": "image/jpeg"
'    },
'    {
'      "kind": "drive#file",
'      "id": "0B53Q6OSTWYolMWt2VzN0Qlo1UjA",
'      "name": "hamlet2.xml",
'      "mimeType": "text/xml"
'    },
' ...
'    {
'      "kind": "drive#file",
'      "id": "0B53Q6OSTWYolc3RhcnRlcl9maWxlX2Rhc2hlclYw",
'      "name": "Getting started",
'      "mimeType": "application/pdf"
'    }
'  ]
' }

outFile.Close