(VBScript) Get File Metadata

Gets a file's metadata or content by ID.

See Google Drive Files get for additional details.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 1

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' Google Drive scope.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.AccessToken = "GOOGLE-DRIVE-ACCESS-TOKEN"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
' A single REST object, once connected, can be used for many Google Drive REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

' ------------------------------------------------------------------------------

' We need to send a GET request like this:
' GET https://www.googleapis.com/drive/v3/files/fileId
' The fileId is part of the path.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/drive/v3/files/")
' Assume we previously obtained the fileId for the file of interest...
success = sbPath.Append("0B53Q6OSTWYolbUF6WS1Gei1oalk")

' Indicate that we want ALL possible fields.
' If no fields are indicated, then only the basic fields are returned.
allFields = "appProperties,capabilities,contentHints,createdTime,description,explicitlyTrashed,fileExtension,folderColorRgb,fullFileExtension,headRevisionId,iconLink,id,imageMediaMetadata,isAppAuthorized,kind,lastModifyingUser,md5Checksum,mimeType,modifiedByMeTime,modifiedTime,name,originalFilename,ownedByMe,owners,parents,permissions,properties,quotaBytesUsed,shared,sharedWithMeTime,sharingUser,size,spaces,starred,thumbnailLink,trashed,version,videoMediaMetadata,viewedByMe,viewedByMeTime,viewersCanCopyContent,webContentLink,webViewLink,writersCanShare"

success = rest.AddQueryParam("fields",allFields)

jsonResponse = rest.FullRequestNoBody("GET",sbPath.GetAsString())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response JSON: " & jsonResponse)
    WScript.Quit
End If

' ---------------------------------------------------
' Sample code for parsing this JSON is shown below...
' ---------------------------------------------------

' A successful response looks like this:
' {
'   "kind": "drive#file",
'   "id": "0B53Q6OSTWYolbUF6WS1Gei1oalk",
'   "name": "penguins.jpg",
'   "mimeType": "image/jpeg",
'   "starred": false,
'   "trashed": false,
'   "explicitlyTrashed": false,
'   "parents": [
'     "0B53Q6OSTWYola296ODZUSm5GYU0"
'   ],
'   "spaces": [
'     "drive"
'   ],
'   "version": "672",
'   "webContentLink": "https://docs.google.com/a/chilkatcloud.com/uc?id=0B53Q6OSTWYolbUF6WS1Gei1oalk&export=download",
'   "webViewLink": "https://drive.google.com/a/chilkatcloud.com/file/d/0B53Q6OSTWYolbUF6WS1Gei1oalk/view?usp=drivesdk",
'   "iconLink": "https://ssl.gstatic.com/docs/doclist/images/icon_11_image_list.png",
'   "thumbnailLink": "https://lh5.googleusercontent.com/uIV1dJdc8vsAQzaaIInpc9AV55AcdHhpM7fQeI2RN2qbCSnhjK9IDdNQAOTtkvjS9ZObqw=s220",
'   "viewedByMe": true,
'   "viewedByMeTime": "2016-10-08T12:38:02.258Z",
'   "createdTime": "2016-10-08T12:38:02.258Z",
'   "modifiedTime": "2016-10-08T12:38:02.258Z",
'   "modifiedByMeTime": "2016-10-08T12:38:02.258Z",
'   "owners": [
'     {
'       "kind": "drive#user",
'       "displayName": "Matthew Smith",
'       "me": true,
'       "permissionId": "08366696655122259092",
'       "emailAddress": "support@chilkatcloud.com"
'     }
'   ],
'   "lastModifyingUser": {
'     "kind": "drive#user",
'     "displayName": "Matthew Smith",
'     "me": true,
'     "permissionId": "08366696655122259092",
'     "emailAddress": "support@chilkatcloud.com"
'   },
'   "shared": false,
'   "ownedByMe": true,
'   "capabilities": {
'     "canEdit": true,
'     "canComment": true,
'     "canShare": true,
'     "canCopy": true,
'     "canReadRevisions": true
'   },
'   "viewersCanCopyContent": true,
'   "writersCanShare": true,
'   "permissions": [
'     {
'       "kind": "drive#permission",
'       "id": "08366696655122259092",
'       "type": "user",
'       "emailAddress": "support@chilkatcloud.com",
'       "role": "owner",
'       "displayName": "Matthew Smith"
'     }
'   ],
'   "originalFilename": "penguins.jpg",
'   "fullFileExtension": "jpg",
'   "fileExtension": "jpg",
'   "md5Checksum": "9d377b10ce778c4938b3c7e2c63a229a",
'   "size": "777835",
'   "quotaBytesUsed": "777835",
'   "headRevisionId": "0B53Q6OSTWYolUUlHVFhHdFlXQ0R1aHZuT0tORTVzc2h5NnZjPQ",
'   "imageMediaMetadata": {
'     "width": 1024,
'     "height": 768,
'     "rotation": 0,
'     "time": "2009:03:12 13:48:35"
'   },
'   "isAppAuthorized": false
' }

' Iterate over each file in the response and show the name, id, and mimeType.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(jsonResponse)

' Show the full JSON response.
json.EmitCompact = 0
outFile.WriteLine(json.Emit())
outFile.WriteLine("-")

' Demonstrate how to get pieces of information:
outFile.WriteLine("Original Filename: " & json.StringOf("originalFilename"))

wasLastModifiedUserMe = json.BoolOf("lastModifyingUser.me")
outFile.WriteLine("Was Last Modified by Me: " & wasLastModifiedUserMe)

' Assuming this is an image file...
width = json.IntOf("imageMediaMetadata.width")
outFile.WriteLine("Image Width: " & width)

' Iterate over parents...

numParents = json.SizeOfArray("parents")
i = 0
Do While i < numParents
    json.I = i
    outFile.WriteLine("Parent " & i & ": " & json.StringOf("parents[i]"))
    i = i + 1
Loop

' Iterate over owners...
numOwners = json.SizeOfArray("owners")
i = 0
Do While i < numOwners
    json.I = i
    outFile.WriteLine("Owner " & i & ": kind=" & json.StringOf("owners[i].kind") & " displayName=" & json.StringOf("owners[i].displayName"))
    i = i + 1
Loop

' Iterate over permissions...
numPermissions = json.SizeOfArray("permissions")
i = 0
Do While i < numPermissions
    json.I = i
    outFile.WriteLine("Permission " & i & ": kind=" & json.StringOf("permissions[i].kind") & " id=" & json.StringOf("permissions[i].id"))
    i = i + 1
Loop

outFile.Close