(VBScript) Download Text File to a String Variable

This example demonstrates how to download the content of a text file from Google Drive into a string variable.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 1

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' Google Drive scope.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.AccessToken = "GOOGLE-DRIVE-ACCESS-TOKEN"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
' A single REST object, once connected, can be used for many Google Drive REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

' ------------------------------------------------------------------------------
' To download a file, we must know the file ID.
' In a previous example (see Build Local Metadata Cache
' we built a local cache to make it easy to lookup file IDs given a file path.
' Let's say we want to download "testFolder/abc/123/pigs.json".
' First we lookup the fileId in the cache.  With the fileId, we can download the file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cache")
set gdCache = CreateObject("Chilkat.Cache")
gdCache.Level = 0
gdCache.AddRoot "C:/ckCache/googleDrive"

fileId = gdCache.FetchText("testFolder/abc/123/pigs.json")
If (gdCache.LastMethodSuccess <> 1) Then
    outFile.WriteLine("Filepath not found in cache.")
    WScript.Quit
End If

' We need to send a GET request like this:
' GET https://www.googleapis.com/drive/v3/files/fileId?alt=media
' The fileId is part of the path.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/drive/v3/files/")
success = sbPath.Append(fileId)
success = rest.AddQueryParam("alt","media")

' The FullRequestNoBody returns the file content in the response body.
fileContent = rest.FullRequestNoBody("GET",sbPath.GetAsString())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    WScript.Quit
End If

outFile.WriteLine(fileContent)

outFile.WriteLine("File downloaded.")

outFile.Close