(VBScript) Google Contacts - Retrieve as JSON

Demonstrates how to retrieve Google Contacts as JSON.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------------------------------
' Note: The code for setting up the Chilkat REST object and making the initial connection can be done once.
' Once connected, the REST object may be re-used for many REST API calls.
' (It's a good idea to put the connection setup code in a separate function/subroutine.)
' --------------------------------------------------------------------------------------------------------

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Google Contacts OAuth2 Access Token

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/googleContacts.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load googleContacts.json")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.AccessToken = jsonToken.StringOf("access_token")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.google.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

' ----------------------------------------------
' OK, the REST connection setup is completed..
' ----------------------------------------------

' To retrieve the contacts, we need to send the following:

' 	GET /m8/feeds/contacts/default/full
' 	GData-Version: 3.0

' To get the contacts data in JSON format, set the "alt" query parameter to "json"
success = rest.AddQueryParam("alt","json")
success = rest.AddHeader("GData-Version","3.0")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponseBody = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestNoBodySb("GET","/m8/feeds/contacts/default/full",sbResponseBody)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & sbResponseBody.GetAsString())
    WScript.Quit
End If

' If the 200 response was received, then the contacts JSON is contained
' in the response body.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.LoadSb(sbResponseBody)
json.EmitCompact = 0

' Save the pretty-printed JSON response to a file.
sbResponseBody.Clear 
success = json.EmitSb(sbResponseBody)
success = sbResponseBody.WriteFile("qa_output/google_contacts.json","utf-8",0)

' Parse the Google Contacts JSON, and iterate over the contacts..
totalResults = json.IntOf("feed.openSearch$totalResults.$t")
startIndex = json.IntOf("feed.openSearch$startIndex.$t")
itemsPerPage = json.IntOf("feed.openSearch$itemsPerPage.$t")
outFile.WriteLine("totalResults = " & totalResults)
outFile.WriteLine("startIndex = " & startIndex)
outFile.WriteLine("itemsPerPage = " & itemsPerPage)

numEntries = json.SizeOfArray("feed.entry")
i = 0
Do While i < numEntries
    json.I = i
    outFile.WriteLine((i + 1) & " ----")
    outFile.WriteLine("title: " & json.StringOf("feed.entry[i].title.$t"))

    fullName = json.StringOf("feed.entry[i].gd$name.gd$fullName.$t")
    If (json.LastMethodSuccess = 1) Then
        outFile.WriteLine("fullName: " & fullName)
    End If

    ' There can be multiple email addresses, so it's stored as a JSON array..
    numEmailAddresses = json.SizeOfArray("feed.entry[i].gd$email")
    j = 0
    Do While j < numEmailAddresses
        emailAddress = json.StringOf("feed.entry[i].gd$email[j].address")
        If (json.LastMethodSuccess = 1) Then
            outFile.WriteLine("email address: " & emailAddress)
        End If

        j = j + 1
    Loop

    i = i + 1
Loop

' A sample Google Contacts JSON response:

' 	{ 
' 	  "version": "1.0",
' 	  "encoding": "UTF-8",
' 	  "feed": { 
' 	    "xmlns": "http://www.w3.org/2005/Atom",
' 	    "xmlns$openSearch": "http://a9.com/-/spec/opensearch/1.1/",
' 	    "xmlns$gContact": "http://schemas.google.com/contact/2008",
' 	    "xmlns$batch": "http://schemas.google.com/gdata/batch",
' 	    "xmlns$gd": "http://schemas.google.com/g/2005",
' 	    "gd$etag": "\"QHw5eTVSLyt7I2A9XRFaE0kNTwI.\"",
' 	    "id": { 
' 	      "$t": "chilkat.support@gmail.com"
' 	    },
' 	    "updated": { 
' 	      "$t": "2016-11-17T01:57:41.221Z"
' 	    },
' 	    "category": [
' 	      { 
' 	        "scheme": "http://schemas.google.com/g/2005#kind",
' 	        "term": "http://schemas.google.com/contact/2008#contact"
' 	      }
' 	    ],
' 	    "title": { 
' 	      "$t": "Chilkat Support's Contacts"
' 	    },
' 	    "link": [
' 	      { 
' 	        "rel": "alternate",
' 	        "type": "text/html",
' 	        "href": "https://www.googleapis.com/"
' 	      },
' 	      { 
' 	        "rel": "http://schemas.google.com/g/2005#feed",
' 	        "type": "application/atom+xml",
' 	        "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full"
' 	      },
' 	      { 
' 	        "rel": "http://schemas.google.com/g/2005#post",
' 	        "type": "application/atom+xml",
' 	        "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full"
' 	      },
' 	      { 
' 	        "rel": "http://schemas.google.com/g/2005#batch",
' 	        "type": "application/atom+xml",
' 	        "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full/batch"
' 	      },
' 	      { 
' 	        "rel": "self",
' 	        "type": "application/atom+xml",
' 	        "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full?max-results=25&alt=json"
' 	      },
' 	      { 
' 	        "rel": "next",
' 	        "type": "application/atom+xml",
' 	        "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full?max-results=25&alt=json&start-index=26"
' 	      }
' 	    ],
' 	    "author": [
' 	      { 
' 	        "name": { 
' 	          "$t": "Chilkat Support"
' 	        },
' 	        "email": { 
' 	          "$t": "chilkat.support@gmail.com"
' 	        }
' 	      }
' 	    ],
' 	    "generator": { 
' 	      "version": "1.0",
' 	      "uri": "http://www.google.com/m8/feeds",
' 	      "$t": "Contacts"
' 	    },
' 	    "openSearch$totalResults": { 
' 	      "$t": "350"
' 	    },
' 	    "openSearch$startIndex": { 
' 	      "$t": "1"
' 	    },
' 	    "openSearch$itemsPerPage": { 
' 	      "$t": "25"
' 	    },
' 	    "entry": [
' 	      { 
' 	        "id": { 
' 	          "$t": "http://www.google.com/m8/feeds/contacts/chilkat.support%40gmail.com/base/0"
' 	        },
' 	        "gd$etag": "\"SX8zcTVSLyt7I2A9WxBXFU4MQwI.\"",
' 	        "updated": { 
' 	          "$t": "2010-01-26T20:07:48.189Z"
' 	        },
' 	        "app$edited": { 
' 	          "xmlns$app": "http://www.w3.org/2007/app",
' 	          "$t": "2010-01-26T20:07:48.189Z"
' 	        },
' 	        "category": [
' 	          { 
' 	            "scheme": "http://schemas.google.com/g/2005#kind",
' 	            "term": "http://schemas.google.com/contact/2008#contact"
' 	          }
' 	        ],
' 	        "title": { 
' 	          "$t": "Joe Sample"
' 	        },
' 	        "link": [
' 	          { 
' 	            "rel": "http://schemas.google.com/contacts/2008/rel#photo",
' 	            "type": "image/*",
' 	            "href": "https://www.googleapis.com/m8/feeds/photos/media/chilkat.support%40gmail.com/0"
' 	          },
' 	          { 
' 	            "rel": "self",
' 	            "type": "application/atom+xml",
' 	            "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full/0"
' 	          },
' 	          { 
' 	            "rel": "edit",
' 	            "type": "application/atom+xml",
' 	            "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full/0"
' 	          }
' 	        ],
' 	        "gd$name": { 
' 	          "gd$fullName": { 
' 	            "$t": "Joe Sample"
' 	          },
' 	          "gd$givenName": { 
' 	            "$t": "Joe"
' 	          },
' 	          "gd$familyName": { 
' 	            "$t": "Sample"
' 	          }
' 	        },
' 	        "gd$email": [
' 	          { 
' 	            "address": "somebody@gmail.com",
' 	            "primary": "true",
' 	            "rel": "http://schemas.google.com/g/2005#other"
' 	          }
' 	        ]
' 	      },
' 		... more entries ...
' 	

outFile.Close