(VBScript) Find Contact Having Email Address

Demonstrates how to fetch the Google Contact for a given email address.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------------------------------
' Note: The code for setting up the Chilkat REST object and making the initial connection can be done once.
' Once connected, the REST object may be re-used for many REST API calls.
' (It's a good idea to put the connection setup code in a separate function/subroutine.)
' --------------------------------------------------------------------------------------------------------

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Google Contacts OAuth2 Access Token

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/googleContacts.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load googleContacts.json")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.AccessToken = jsonToken.StringOf("access_token")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.google.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

' ----------------------------------------------
' OK, the REST connection setup is completed..
' ----------------------------------------------

' To retrieve the contacts, we need to send the following:

' 	GET /m8/feeds/contacts/default/full?q=<emailAddress>
' 	GData-Version: 3.0

' Get the contact (or contacts) with this email address:
emailAddressToFind = "admin@chilkatsoft.com"

success = rest.AddHeader("GData-Version","3.0")
success = rest.AddQueryParam("q",emailAddressToFind)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponseBody = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestNoBodySb("GET","/m8/feeds/contacts/default/full",sbResponseBody)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & sbResponseBody.GetAsString())
    WScript.Quit
End If

' If the 200 response was received, then the contacts XML is contained
' in the response body.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadSb(sbResponseBody,0)

' See below for a sample response body.
success = xml.SaveXml("qa_output/google_contacts.xml")

' Now let's parse the XML...

' Get the the total number of results, the start index, and the items per page.
' We'll likely NOT get the full list, but will instead get the 1st page.
totalResults = xml.GetChildIntValue("openSearch:totalResults")
startIndex = xml.GetChildIntValue("openSearch:startIndex")
itemsPerPage = xml.GetChildIntValue("openSearch:itemsPerPage")
outFile.WriteLine("totalResults = " & totalResults)
outFile.WriteLine("startIndex = " & startIndex)
outFile.WriteLine("itemsPerPage = " & itemsPerPage)

' We'll borrow a method from FileAccess to get the contactId from the URL string (see the code in the while loop)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")

' Iterate over each contact.
numEntries = xml.NumChildrenHavingTag("entry")
i = 0
Do While i < numEntries
    xml.I = i
    outFile.WriteLine((i + 1) & " ----")
    outFile.WriteLine("title: " & xml.GetChildContent("entry[i]|title"))

    ' The entry "id" child contains a URL having this format:
    ' <id>http://www.google.com/m8/feeds/contacts/{userEmail}/base/{contactId}</id>
    ' Let's get the URL and parse the contactId from it..
    idUrl = xml.GetChildContent("entry[i]|id")
    outFile.WriteLine("id: " & idUrl)

    ' Use the parsing ability of GetFileName to get the contactId
    contactId = fac.GetFileName(idUrl)
    outFile.WriteLine("contactId: " & contactId)

    fullName = xml.ChilkatPath("entry[i]|gd:name|gd:fullName|*")
    If (xml.LastMethodSuccess = 1) Then
        outFile.WriteLine("fullName: " & fullName)
    End If

    emailAddress = xml.ChilkatPath("entry[i]|gd:email|(address)")
    If (xml.LastMethodSuccess = 1) Then
        outFile.WriteLine("email address: " & emailAddress)
    End If

    i = i + 1
Loop

outFile.Close