(VBScript) Upload In-Memory Binary Data to Google Cloud Storage

Demonstrates how to upload in-memory binary data to Google Cloud Storage.

Note: This example requires Chilkat v9.5.0.69 or later because it uses the http.PBinaryBd method.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' scope "https://www.googleapis.com/auth/cloud-platform"

' In this example, Get Google Cloud Storage OAuth2 Access Token, 
' the service account access token was saved to a text file.  This example fetches the access token from the file..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbToken = CreateObject("Chilkat.StringBuilder")
success = sbToken.LoadFile("qa_data/tokens/googleCloudStorageAccessToken.txt","utf-8")

' Send a POST equivalent to this curl command.
' The content of the file is contained in the request body.

' curl -X POST --data-binary @[OBJECT] \
'     -H "Authorization: Bearer [OAUTH2_TOKEN]" \
'     -H "Content-Type: [OBJECT_CONTENT_TYPE]" \
'     "https://www.googleapis.com/upload/storage/v1/b/[BUCKET_NAME]/o?uploadType=media&name=[OBJECT_NAME]"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Download a JPG image from the Internet, and then upload this JPG to
' a Google Storage bucket.
jpgUrl = "https://www.chilkatsoft.com/images/starfish.jpg"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set jpgData = CreateObject("Chilkat.BinData")
success = http.DownloadBd(jpgUrl,jpgData)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

http.AuthToken = sbToken.GetAsString()

' Construct a URL to upload to an object named "starfish.jpg" in the "chilkat-ocean" bucket.
success = http.SetUrlVar("bucket_name","chilkat-ocean")
success = http.SetUrlVar("object_name","starfish.jpg")
url = "https://www.googleapis.com/upload/storage/v1/b/{$bucket_name}/o?uploadType=media&name={$object_name}"

' Note: The PBinaryBd method first appears in Chilkat v9.5.0.69
' resp is a Chilkat.HttpResponse
Set resp = http.PBinaryBd("POST",url,jpgData,"image/jpeg",0,0)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

responseCode = resp.StatusCode
If (responseCode = 401) Then
    outFile.WriteLine(resp.BodyStr)
    outFile.WriteLine("If invalid credentials, then it is likely the access token expired.")
    outFile.WriteLine("Your app should automatically fetch a new access token and re-try.")

    WScript.Quit
End If

outFile.WriteLine("Response code: " & responseCode)
outFile.WriteLine("Response body")
outFile.WriteLine(resp.BodyStr)

' A successful response looks like this:
' Response code: 200
' Response body
' {
'  "kind": "storage#object",
'  "id": "chilkat-ocean/starfish.jpg/1502670320090292",
'  "selfLink": "https://www.googleapis.com/storage/v1/b/chilkat-ocean/o/starfish.jpg",
'  "name": "starfish.jpg",
'  "bucket": "chilkat-ocean",
'  "generation": "1502670320090292",
'  "metageneration": "1",
'  "contentType": "image/jpeg",
'  "timeCreated": "2017-08-14T00:25:20.040Z",
'  "updated": "2017-08-14T00:25:20.040Z",
'  "storageClass": "MULTI_REGIONAL",
'  "timeStorageClassUpdated": "2017-08-14T00:25:20.040Z",
'  "size": "6229",
'  "md5Hash": "LpxZ2/JmI2fcl9/dqF2gSA==",
'  "mediaLink": "https://www.googleapis.com/download/storage/v1/b/chilkat-ocean/o/starfish.jpg?generation=1502670320090292&alt=media",
'  "crc32c": "9RjgwQ==",
'  "etag": "CLT5kpW71dUCEAE="
' }


outFile.Close