(VBScript) Automatically Refresh Token for 401 Unauthorized

Demonstrates how to automatically refresh an access token (without user interaction) when the token expires and a 401 Unauthorized response is received.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

tokenFilePath = "qa_data/tokens/googleCalendar.json"

' Get our current access token.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile(tokenFilePath)
If (jsonToken.HasMember("access_token") = 0) Then
    outFile.WriteLine("No access token found.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
http.AuthToken = jsonToken.StringOf("access_token")

jsonResponse = http.QuickGetStr("https://www.googleapis.com/calendar/v3/users/me/calendarList")
If (http.LastMethodSuccess <> 1) Then

    If (http.LastStatus <> 401) Then
        outFile.WriteLine(http.LastErrorText)
        outFile.WriteLine("----")
        outFile.WriteLine(http.LastResponseBody)
        WScript.Quit
    End If

    ' The access token must've expired. 
    ' Refresh the access token and then retry the request.
    ' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.OAuth2")
    set oauth2 = CreateObject("Chilkat.OAuth2")

    oauth2.TokenEndpoint = "https://www.googleapis.com/oauth2/v4/token"

    ' Replace these with actual values.
    oauth2.ClientId = "GOOGLE-CLIENT-ID"
    oauth2.ClientSecret = "GOOGLE-CLIENT-SECRET"

    ' Get the "refresh_token"
    oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

    ' Send the HTTP POST to refresh the access token..
    success = oauth2.RefreshAccessToken()
    If (success <> 1) Then
        outFile.WriteLine(oauth2.LastErrorText)
        WScript.Quit
    End If

    ' The response contains a new access token, but we must keep
    ' our existing refresh token for when we need to refresh again in the future.
    success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

    ' Save the new JSON access token response to a file.
    ' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
    set sbJson = CreateObject("Chilkat.StringBuilder")
    jsonToken.EmitCompact = 0
    success = jsonToken.EmitSb(sbJson)
    success = sbJson.WriteFile(tokenFilePath,"utf-8",0)

    outFile.WriteLine("OAuth2 authorization granted!")
    outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

    ' re-try the original request.
    http.AuthToken = oauth2.AccessToken
    jsonResponse = http.QuickGetStr("https://www.googleapis.com/calendar/v3/users/me/calendarList")
    If (http.LastMethodSuccess <> 1) Then
        outFile.WriteLine(http.LastErrorText)
        WScript.Quit
    End If

End If

outFile.WriteLine(jsonResponse)
outFile.WriteLine("-----------------------------")

outFile.Close