(VBScript) Create GMail Draft

Demonstrates how to create a new GMail draft email.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Use the Chilkat Email API to create or load an email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")
email.Subject = "This is a test GMail email created using Chilkat."
email.Charset = "utf-8"
success = email.AddPlainTextAlternativeBody("This is a test")
success = email.AddHtmlAlternativeBody("<html><body><p>This is a <b>test</b></body></html>")

' We'll need to get the full MIME of the email encoded to a base64url string.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbMime = CreateObject("Chilkat.StringBuilder")
success = email.GetMimeSb(sbMime)
success = sbMime.Encode("base64url","utf-8")

' The body of the HTTP request will be JSON..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateSb("message.raw",sbMime)

' Upload the email to GMail as a draft.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
http.AuthToken = "GMAIL-ACCESS-TOKEN"

url = "https://www.googleapis.com/gmail/v1/users/me/drafts"
' resp is a Chilkat.HttpResponse
Set resp = http.PostJson3(url,"application/json",json)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' A status code of 200 indicates success.
outFile.WriteLine("Response status code: " & resp.StatusCode)
outFile.WriteLine("Response body:")
outFile.WriteLine(resp.BodyStr)

' The response body contains JSON.
' Use the online tool at Generate JSON Parsing Code
' to generate JSON parsing code.

' A sample successful JSON response:

' {
'  "id": "r-2607584557788895307",
'  "message": {
'   "id": "166f09932c662e93",
'   "threadId": "166f09932c662e93",
'   "labelIds": [
'    "DRAFT"
'   ]
'  }
' }

outFile.Close