(VBScript) Global Payments Card Authorization

Demonstrates how to send a card payments authorization request.

For more information, see https://developer.globalpay.com/#!/api/card-payments#api-authorisation

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' if you don't have a Client ID yet you can still quickly test some basic request types using the following URL and credentials:

' Test URL - https://test.realexpayments.com/epage-remote.cgi
' Client ID: realexsandbox
' Shared Secret: Po8lRRT67a
testUrl = "https://test.realexpayments.com/epage-remote.cgi"
clientID = "realexsandbox"
sharedSecret = "Po8lRRT67a"

amount = "1001"
currency = "EUR"
cardNumber = "4263970000005262"

' We'll be sending the following XML in the body of the request:

' <?xml version="1.0" encoding="UTF-8"?>
' <request type="auth" timestamp="20180613141207">
'   <merchantid>MerchantId</merchantid>
'   <account>internet</account>
'   <channel>ECOM</channel>
'   <orderid>N6qsk4kYRZihmPrTXWYS6g</orderid>
'   <amount currency="EUR">1001</amount>
'   <card>
'     <number>4263970000005262</number>
'     <expdate>0425</expdate>
'     <chname>James Mason</chname>
'     <type>VISA</type>
'     <cvn>
'       <number>123</number>
'       <presind>1</presind>
'     </cvn>
'   </card>
'   <autosettle flag="1"/>
'   <sha1hash>87707637a34ba651b6185718c863abc64b673f20</sha1hash>
' </request>

' Use this online tool to generate code from sample XML: 
' Generate Code to Create XML

' Get the current date/time in this format:  20180613141207
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dt = CreateObject("Chilkat.CkDateTime")
success = dt.SetFromCurrentSystemTime()
dtStr = dt.GetAsIso8601("YYYYMMDDhhmmss",1)

' Generate a unique order ID
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Prng")
set prng = CreateObject("Chilkat.Prng")
orderId = prng.GenRandom(32,"base64url")

' Compute the sha1hash
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "sha1"
crypt.EncodingMode = "hexlower"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbA = CreateObject("Chilkat.StringBuilder")
success = sbA.Append("timestamp.merchantid.orderid.amount.currency.cardnumber")
numReplaced = sbA.Replace("timestamp",dtStr)
numReplaced = sbA.Replace("merchantid",clientID)
numReplaced = sbA.Replace("orderid",orderId)
numReplaced = sbA.Replace("amount",amount)
numReplaced = sbA.Replace("currency",currency)
numReplaced = sbA.Replace("cardnumber",cardNumber)

hashA = crypt.HashStringENC(sbA.GetAsString())

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbB = CreateObject("Chilkat.StringBuilder")
success = sbB.Append(hashA)
success = sbB.Append(".")
success = sbB.Append(sharedSecret)

hashB = crypt.HashStringENC(sbB.GetAsString())

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "request"
success = xml.AddAttribute("type","auth")
success = xml.AddAttribute("timestamp",dtStr)
xml.UpdateChildContent "merchantid",clientID
xml.UpdateChildContent "account","internet"
xml.UpdateChildContent "channel","ECOM"
xml.UpdateChildContent "orderid",orderId
success = xml.UpdateAttrAt("amount",1,"currency",currency)
xml.UpdateChildContent "amount",amount
xml.UpdateChildContent "card|number",cardNumber
xml.UpdateChildContent "card|expdate","0425"
xml.UpdateChildContent "card|chname","James Mason"
xml.UpdateChildContent "card|type","VISA"
xml.UpdateChildContent "card|cvn|number","123"
xml.UpdateChildContent "card|cvn|presind","1"
success = xml.UpdateAttrAt("autosettle",1,"flag","1")
xml.UpdateChildContent "sha1hash",hashB

' resp is a Chilkat.HttpResponse
Set resp = http.PostXml(testUrl,xml.GetXml(),"utf-8")
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response Status Code: " & resp.StatusCode)

outFile.WriteLine("Response Body:")
outFile.WriteLine(resp.BodyStr)

If (resp.StatusCode <> 200) Then
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' A status code of 200 indicates we received an XML response, but it could be an error message.
' Here's an example of an error response:

' <?xml version="1.0" encoding="UTF-8" standalone="yes"?>
' <response timestamp="20200418142356">
'     <orderid>N6qsk4kYRZihmPrTXWYS6g</orderid>
'     <result>508</result>
'     <message>Invalid timestamp: '{' Value exceeds allowable limit: '}'</message>
' </response>

' We need to check the "result" within the XML.
success = xml.LoadXml(resp.BodyStr)

result = xml.GetChildIntValue("result")
outFile.WriteLine("result = " & result)

' A successful result looks like this:

' <?xml version="1.0" encoding="UTF-8" standalone="yes"?>
' <response timestamp="20200418145519">
'     <merchantid>realexsandbox</merchantid>
'     <account>internet</account>
'     <orderid>Cw93I1nFWVZuaATh46qMUCBlCcfrOvLo65C2cq5X-AY</orderid>
'     <result>00</result>
'     <authcode>L3pHww</authcode>
'     <message>AUTH CODE: L3pHww</message>
'     <pasref>96838535689610806</pasref>
'     <cvnresult>M</cvnresult>
'     <timetaken>87</timetaken>
'     <authtimetaken>67</authtimetaken>
'     <batchid>6322506</batchid>
'     <sha1hash>2fd2f15f97f1775779fe9bda536dc8317a4b39f6</sha1hash>
' </response>

If (result = 0) Then
    outFile.WriteLine("authcode = " & xml.GetChildContent("authcode"))
    outFile.WriteLine("Success.")

Else
    outFile.WriteLine("Failed.")
End If


outFile.Close