(VBScript) Glacier Upload Archive

Demonstrates how to add an archive to a vault. For a successful upload, your data is durably persisted. In response, Amazon S3 Glacier (Glacier) returns the archive ID in the x-amz-archive-id header of the response. You should save the archive ID returned so that you can access the archive later.

Note: This example requires Chilkat v9.5.0.78 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server in the desired region.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("glacier.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "glacier"
authAws.Region = "us-west-2"

success = rest.SetAuthAws(authAws)

' --------------------------------------------------------------------------
' Note: The above REST connection and setup of the AWS credentials
' can be done once.  After connecting, any number of REST calls can be made.
' The "auto reconnect" property passed to rest.Connect indicates that if
' the connection is lost, a REST method call will automatically reconnect
' if needed.
' --------------------------------------------------------------------------

' 
' For more information, see Glacier Upload Archive Reference Documentation
' 
success = rest.AddHeader("x-amz-glacier-version","2012-06-01")

' We'll need to pre-compute the SHA256 tree hash and the SHA256 linear hash.
' The hashes are added in the following request headers:

' x-amz-sha256-tree-hash: SHA256 tree hash
' x-amz-content-sha256: SHA256 linear hash

' The file we'll be uploading
filePath = "qa_data/zips/somethingBig.zip"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "sha256-tree-hash"
crypt.EncodingMode = "hexlower"
treeHashHex = crypt.HashFileENC(filePath)
success = rest.AddHeader("x-amz-sha256-tree-hash",treeHashHex)

crypt.HashAlgorithm = "sha256"
linearHashHex = crypt.HashFileENC(filePath)
authAws.PrecomputedSha256 = linearHashHex

' We can optionally add a description
' In this case, we'll set the description equal to the local filepath of the file we're uploading.
success = rest.AddHeader("x-amz-archive-description",filePath)

' Upload the file to the vault named "chilkat"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Stream")
set fileStream = CreateObject("Chilkat.Stream")
fileStream.SourceFile = filePath

' May need to increase the timeout if this is a really large file..
rest.IdleTimeoutMs = 120000

'  Add an Expect: 100-continue request header
success = rest.AddHeader("Expect","100-continue")

responseStr = rest.FullRequestStream("POST","/AWS_ACCOUNT_ID/vaults/chilkat/archives",fileStream)
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

respStatusCode = rest.ResponseStatusCode
If (respStatusCode >= 400) Then
    outFile.WriteLine("Response Status Code = " & respStatusCode)
    outFile.WriteLine("Response Header:")
    outFile.WriteLine(rest.ResponseHeader)
    outFile.WriteLine("Response Body:")
    outFile.WriteLine(responseStr)
    WScript.Quit
End If

' Success is indicated by a 201 response status with an empty response body.
outFile.WriteLine("response status code = " & respStatusCode)

' If successful, the response header looks like this.
' The Location and x-amz-archive-id are two items of information we may wish to save..

' HTTP/1.1 201 Created
' x-amzn-RequestId: AAABZpJrTyioDC_HsOmHae8EZp_uBSJr6cnGOLKp_XJCl-Q
' Date: Wed, 10 Feb 2017 12:00:00 GMT
' x-amz-sha256-tree-hash: beb0fe31a1c7ca8c6c04d574ea906e3f97b31fdca7571defb5b44dca89b5af60
' Location: /111122223333/vaults/examplevault/archives/NkbByEejwEggmBz2fTH ... GlqrEXAMPLEArchiveId
' x-amz-archive-id: NkbByEejwEggmBz2fTHgJrg0XBoDfjP4q6iu87-TjhqG6eGoOY9Z8i1_AUyUsu ... BfGlqrEXAMPLEArchiveId
' 

archiveId = rest.ResponseHdrByName("x-amz-archive-id")
outFile.WriteLine("x-amz-archive-id = " & archiveId)

location = rest.ResponseHdrByName("Location")
outFile.WriteLine("Location = " & location)

outFile.Close