(VBScript) Geolocation of IP Address

To get information about an IP address, there are various public web services that can be queried. I would also guess that paid-for services exist. In any case, it's likely the service is accessible via a REST API. This example demonstrates a few public geolocation API's, each of which may have limitations on the number of queries per hour/day/etc.

Also, please note that this example was created on 23-Sep-2016. As time goes by, the public services referenced by this example may have changed or disappeared entirely. Make sure to do your research before assuming this example will work. The intent of this example is to give a flavor of what might be possible.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The IP address used in this example is 104.40.211.35
ipAddress = "104.40.211.35"

' First we'll try the service at freegeoip.net.
' They have a limit of 10,000 queries per hour, and also 
' provide free source code to run your own server.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to freegeoip.net
bTls = 0
port = 80
bAutoReconnect = 1
success = rest.Connect("freegeoip.net",port,bTls,bAutoReconnect)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Query the IP address to return JSON.
responseJson = rest.FullRequestNoBody("GET","/json/104.40.211.35")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Just in case we are still connected..
maxWaitMs = 10
success = rest.Disconnect(maxWaitMs)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(responseJson)
json.EmitCompact = 0

outFile.WriteLine(json.Emit())

' The JSON we get back looks like this:
' {
'   "ip": "104.40.211.35",
'   "country_code": "US",
'   "country_name": "United States",
'   "region_code": "WA",
'   "region_name": "Washington",
'   "city": "Redmond",
'   "zip_code": "98052",
'   "time_zone": "America/Los_Angeles",
'   "latitude": 47.6801,
'   "longitude": -122.1206,
'   "metro_code": 819
' }

' Examine a few bits of information:
outFile.WriteLine("country name = " & json.StringOf("country_name"))
outFile.WriteLine("country code = " & json.StringOf("country_code"))

' -----------------------------------------------------
' Now to use ip-api.com, which is mostly the same..

success = rest.Connect("ip-api.com",port,bTls,bAutoReconnect)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Query the IP address to return JSON.
responseJson = rest.FullRequestNoBody("GET","/json/104.40.211.35")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Just in case we are still connected..
success = rest.Disconnect(maxWaitMs)

success = json.Load(responseJson)
json.EmitCompact = 0

outFile.WriteLine(json.Emit())

' The JSON we get back looks like this:
' This is very strange, because the two services don't agree.
' {
'   "as": "AS8075 Microsoft Corporation",
'   "city": "Amsterdam",
'   "country": "Netherlands",
'   "countryCode": "NL",
'   "isp": "Microsoft Corporation",
'   "lat": 52.35,
'   "lon": 4.9167,
'   "org": "Microsoft Azure",
'   "query": "104.40.211.35",
'   "region": "NH",
'   "regionName": "North Holland",
'   "status": "success",
'   "timezone": "Europe/Amsterdam",
'   "zip": "1091"
' }

' Examine a few bits of information:
outFile.WriteLine("country name = " & json.StringOf("country"))
outFile.WriteLine("country code = " & json.StringOf("countryCode"))

outFile.Close