VBScript

Verify FTP SSL Server Certificate

See more FTP Examples

This example demonstrates how to verify the FTP server's certificate and authenticity. The intent is to verify the authenticity of the server before passing a login/password to it. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.myftpserver.com"
ftp.Username = "myUsername"
ftp.Password = "myPassword"

' Establish an AUTH SSL secure channel after connection
' on the standard FTP port 21.
ftp.AuthSsl = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Do not set it.
ftp.Ssl = 0

' Indicate that the FTP server must have a verifiable SSL certificate.
' Do not accept self-signed certs or certificates that are
' expired, revoked, or cannot be verified to a root authority:
ftp.RequireSslCertVerify = 1

' You may also set a requirement.  In this example,
' the certificate's Common Name (CN) must match the
' required string exactly:
ftp.SetSslCertRequirement "subjectcn","Chilkat Software, Inc."

' Connect and login to the FTP server.
success = ftp.Connect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' After logging on, you may examine the FTP server's cert:
set cert = CreateObject("Chilkat.Cert")
success = ftp.GetServerCert(cert)
If (success = 0) Then
    outFile.WriteLine("No server certificate!")
Else
    ' Display the distinguished name of the SSL cert.
    outFile.WriteLine(cert.SubjectDN)
End If

outFile.WriteLine("Secure FTP Channel Established!")

' Do whatever you're doing to do ...
' upload files, download files, etc...

success = ftp.Disconnect()

outFile.Close