(VBScript) Upload to Tumbleweed SecureTransport FTPS Server

Demonstrates how to connect, authenticate, and upload file to a Tumbleweed Secure Transport SSL FTP Server. Instead of providing a login name and password, you pass the string "site-auth" for the username, and an empty string for the password. You must also provide a client-side digital certificate -- as the certificate's credentials and validity are used to authenticate.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ftp2")
set ftp = CreateObject("Chilkat.Ftp2")

' This code has been tested with the Tumbleweed server
' at sft.wellsfargo.com
ftp.Hostname = "sft.wellsfargo.com"

' Use these exact strings for the username and password:
ftp.Username = "site-auth"
ftp.Password = ""

' Establish an AUTH SSL secure channel after connecting.
' Your client-side certificate is used for authentication when
' the SSL channel is established.
ftp.AuthSsl = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Do not set it.
ftp.Ssl = 0

' Load a certificate from a .pfx
' A PFX may contain several certs, including the certificates
' in a chain of authority.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CertStore")
set certStore = CreateObject("Chilkat.CertStore")
password = "***"
' Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("my.pfx",password)
If (success <> 1) Then
    outFile.WriteLine(certStore.LastErrorText)
    WScript.Quit
End If

' Find the exact cert we'll use:
' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("My Certificate 123 ABC")
If (certStore.LastMethodSuccess = 0) Then
    outFile.WriteLine("Certificate not found!")
    WScript.Quit
End If

' Tell the Chilkat FTP2 component to use the client-side
' cert for the SSL connection:
success = ftp.SetSslClientCert(cert)

' Connect and authenticate with the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
Else
    ' LastErrorText contains information even when
    ' successful. This allows you to visually verify
    ' that the secure connection actually occurred.
    outFile.WriteLine(ftp.LastErrorText)
End If

outFile.WriteLine("Secure FTP Channel Established!")

' Change to the remote directory where the file will be
' uploaded.  If your file is to be uploaded to the FTP user 
' account's home directory, this is not necessary.
success = ftp.ChangeRemoteDir("someSubDir")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' You may include an absolute or relative path with the 
' local filename.  If no path is included, the file should 
' be present in the current working directory of the calling
' process.
localFilename = "someFile.dat"
remoteFilename = "someFile.dat"

' Upload the file.
success = ftp.PutFile(localFilename,remoteFilename)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.Disconnect()

outFile.Close