(VBScript) Using the FTP Session Log

The Chilkat FTP component can keep a session log if the KeepSessionLog property is turned on. This is helpful in debugging problems. Chilkat support will usually ask for a session log when working to resolve your problem, because it contains a log of the exact commands sent to the FTP server, and the exact responses received.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ftp2")
set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Set the KeepSessionLog property in order to keep a session log.
' The session log will continuously grow in memory.  The
' ClearSessionLog method may be called to clear it.  The session
' logging may be turned on/off at any point.
ftp.KeepSessionLog = 1

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Change to the remote directory where the existing file is located.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' To clear the SessionLog at any point, call ClearSessionLog:
' call ftp.ClearSessionLog();

' Append moreHamlet.txt to hamlet.txt on the FTP server.
localFilename = "moreHamlet.txt"
remoteFilename = "hamlet.txt"

success = ftp.AppendFile(localFilename,remoteFilename)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.Disconnect()

' Display the entire session log:
outFile.WriteLine(ftp.SessionLog)

outFile.WriteLine("File Appended!")

outFile.Close