VBScript

FTP Iterate over Files in Directory Matching ListPattern

See more RSA Examples

Uses the ListPattern property to iterate over the files in a directory matching the pattern. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "my_login"
ftp.Password = "my_password"
ftp.Port = 21
ftp.AuthTls = 1

success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Change to the "images" sub-directory located under our FTP account's home directory.
success = ftp.ChangeRemoteDir("images")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

ftp.ListPattern = "*.png"

' Fetch the current remote directory contents by calling GetDirCount
n = ftp.GetDirCount()
If (n < 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

i = 0

set sbLocalPath = CreateObject("Chilkat.StringBuilder")

Do While i < n
    filename = ftp.GetFilename(i)
    outFile.WriteLine(filename)

    ' Download this file.
    success = sbLocalPath.SetString("qa_output/")
    success = sbLocalPath.Append(filename)
    success = ftp.GetFile(filename,sbLocalPath.GetAsString())
    If (success <> 1) Then
        outFile.WriteLine(ftp.LastErrorText)
        WScript.Quit
    End If

    i = i + 1
Loop

outFile.Close