(VBScript) Inovis VAN FTP/SSL (EDI)

Demonstrates how to connect to the Inovis EDI VAN (FTP/SSL).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ftp2")
set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftpssl.gateway.inovisworks.net"
ftp.Username = "myLogin"
ftp.Password = "myPassword"

' The Inovis EDI VAN requires Passive connections:
ftp.Passive = 1

' Note: The Inovis documentation mentions an outbound
' high port range of 40000-49999.  In passive mode, the
' FTP server chooses the port number for the data
' connection.  The Inovis server will choose a port number
' in the range 40000-49999.  To establish the data connection,
' your firewall must allow outgoing connections in that port
' range. 

' This tells Chilkat FTP2 to establish
' an AUTH TLS secure channel after connecting
' on the standard FTP port 21.
ftp.AuthTls = 1

' You'll probably need this property set to 1 if you're
' behind a NAT router or firewall.
ftp.PassiveUseHostAddr = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Do not set it to 1.  The Inovis VAN
' uses explicit encryption (SSL/TLS).
ftp.Ssl = 0

' The Chilkat FTP component automatically sends a "FEAT";
' command after connecting.  This allows the component
' to better know the FTP server's capabilities.
' The Invois server doesn't recognize the FEAT command,
' so disable it:
ftp.AutoFeat = 0

' Connect, convert to TLS, and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
Else
    ' LastErrorText contains information even when
    ' successful. This allows you to visually verify
    ' that the secure connection actually occurred.
    outFile.WriteLine(ftp.LastErrorText)
End If

outFile.WriteLine("Connection to Inovis EDI VAN OK!")

' Do whatever you're doing to do ...
' upload files, download files, etc...

success = ftp.Disconnect()

outFile.Close