VBScript

FTP through HTTP Tunnel (FTP over HTTP Proxy)

See more FTP Examples

Note: This example requires Chilkat v9.5.0.51 or greater.

FTP through an HTTP tunnel (via an HTTP proxy server that supports HTTP tunneling).

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Set the HTTP proxy server properties.
' This is to connect via HTTP/1.1 using CONNECT method
ftp.HttpProxyHostname = "192.168.1.127"
ftp.HttpProxyPort = 8080

' If the proxy server requires authentication...
ftp.HttpProxyUsername = "myProxyUsername"
ftp.HttpProxyPassword = "myProxyPassword"

' FTP over an HTTP proxy requires that FTP Passive mode be used
' for data transfers. It is not possible to use non-passive (active) mode
' for FTP over HTTP.
ftp.Passive = 1

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Change to the remote directory where the file will be uploaded.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Upload a file.
localFilename = "c:/temp/hamlet.xml"
remoteFilename = "hamlet.xml"

success = ftp.PutFile(localFilename,remoteFilename)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.Disconnect()

outFile.WriteLine("File Uploaded!")

outFile.Close