(VBScript) FTP Download Binary File to a Stream

Demonstrates how to FTP download a binary file to a Chilkat stream.

Note: This example requires Chilkat v9.5.0.67 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat FTP2 API to have been previously unlocked.
' See FTP2 Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ftp2")
set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "www.my-ftp-server.com"
ftp.Username = "mFtpLogin"
ftp.Password = "myFtpPassword"
ftp.AuthTls = 1
ftp.Passive = 1

' Connect and login to the FTP server using TLS.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' We'll read the incoming data chunk-by-chunk and write to an output file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
success = fac.OpenForWrite("qa_output/penguins2.jpg")
If (success <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Stream")
set streamObj = CreateObject("Chilkat.Stream")

' Create a task to do the FTP download.
' t is a Chilkat.Task
Set t = ftp.GetFileToStreamAsync("penguins2.jpg",streamObj)
If (ftp.LastMethodSuccess <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Start the task in a background thread.
success = t.Run()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
Do While streamObj.EndOfStream <> 1
    ' Get the next chunk of JPG bytes.
    success = streamObj.ReadBd(bd)
    ' Do something with it..
    ' In this simple example, we'll just write to the file.
    success = fac.FileWriteBd(bd,0,0)
    ' Clear for the next read.
    success = bd.Clear()
Loop

fac.FileClose 

outFile.WriteLine("Success.")

outFile.Close