VBScript

FatturaPA XML Invoice Sign+Encrypt to P7M

See more Digital Signatures Examples

Demonstrates how to create a CAdES BES signed + encrypted invoice.xml.p7m for the Italian FatturaPA exchange system. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

' Use a digital certificate and private key from a PFX file (.pfx or .p12).
pfxPath = "qa_data/pfx/cert_test123.pfx"
pfxPassword = "test123"

set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Provide the signing cert (with associated private key).
success = crypt.SetSigningCert(cert)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Indicate that SHA-256 should be used.
crypt.HashAlgorithm = "sha256"

' Specify the signed attributes to be included.
' (This is what makes it CAdES-BES compliant.)
set jsonSignedAttrs = CreateObject("Chilkat.JsonObject")
success = jsonSignedAttrs.UpdateInt("contentType",1)
success = jsonSignedAttrs.UpdateInt("signingTime",1)
success = jsonSignedAttrs.UpdateInt("messageDigest",1)
success = jsonSignedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

inFile = "qa_data/xml/IT01234567890_11002.xml"
sigFile = "qa_data/fatturapa/signed.p7m"

' Create the CAdES-BES signature, which contains the original data.
success = crypt.CreateP7M(inFile,sigFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Now we'll encrypt what was signed using FatturaPA's certificate (from a PEM file)
set encryptCert = CreateObject("Chilkat.Cert")
success = encryptCert.LoadFromFile("qa_data/certs/fatturapa_cert.pem")
If (success = 0) Then
    outFile.WriteLine(encryptCert.LastErrorText)
    WScript.Quit
End If

crypt.CryptAlgorithm = "pki"

success = crypt.SetEncryptCert(encryptCert)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Indicate the underlying bulk encryption algorithm to be used:
crypt.Pkcs7CryptAlg = "aes"
crypt.KeyLength = 128

' There's one last option that could be set.  If is the RSA encryption encryption/padding scheme. 
' By default, RSAES_PKCS1-V1_5 is used.  If desired, the OaepPadding property could be set to 1 to
' use RSAES_OAEP.  (We'll leave it set at the default value of 0)
crypt.OaepPadding = 0

' Everything is specified.  Encrypt the .p7m to create a new .p7m (which adds a layer of encryption around the opaque signature).
' The output is PKCS7 in binary DER format.
success = crypt.CkEncryptFile(sigFile,"qa_output/signed_and_encrypted.p7m")
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close