VBScript

Create CAdES-BES .p7m for FatturaPA XML Invoice

See more Digital Signatures Examples

Demonstrates how to create a CAdES BES invoice.xml.p7m for the Italian FatturaPA exchange system.

Note: This example requires Chilkat v9.5.0.75.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Note: Requires Chilkat v9.5.0.75 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

' Use a digital certificate and private key from a PFX file (.pfx or .p12).
pfxPath = "qa_data/pfx/cert_test123.pfx"
pfxPassword = "test123"

set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Provide the signing cert (with associated private key).
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Indicate that SHA-256 should be used.
crypt.HashAlgorithm = "sha256"

' Specify the signed attributes to be included.
' (This is what makes it CAdES-BES compliant.)
set jsonSignedAttrs = CreateObject("Chilkat.JsonObject")
success = jsonSignedAttrs.UpdateInt("contentType",1)
success = jsonSignedAttrs.UpdateInt("signingTime",1)
success = jsonSignedAttrs.UpdateInt("messageDigest",1)
success = jsonSignedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

inFile = "qa_data/xml/IT01234567890_11002.xml"
sigFile = "qa_output/IT01234567890_11002.xml.p7m"

' Create the CAdES-BES signature, which contains the original data.
success = crypt.CreateP7M(inFile,sigFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close