VBScript

Get the Photos for a User

See more Facebook Examples

Demonstrates how to get the photos that the user has uploaded. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a previously obtained an access token
set oauth2 = CreateObject("Chilkat.OAuth2")
oauth2.AccessToken = "FACEBOOK-ACCESS-TOKEN"

set rest = CreateObject("Chilkat.Rest")

' Connect to Facebook.
success = rest.Connect("graph.facebook.com",443,1,1)
If (success = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthOAuth2(oauth2)

' Indicate that we only want the photos the user has personally uploaded.
success = rest.AddQueryParam("type","uploaded")

' We could limit the number of photos by setting a limit.
success = rest.AddQueryParam("limit","5")

' Gets the 1st page of photos. (Not the actual image data, but the information about each photo.)
' See https://developers.facebook.com/docs/graph-api/reference/user/photos/ for more information.
responseJson = rest.FullRequestNoBody("GET","/v2.7/me/photos")
If (rest.LastMethodSuccess = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0
success = json.Load(responseJson)
outFile.WriteLine(json.Emit())

' A sample JSON response is shown below.  
' This is the code to parse the JSON response.

set dtime = CreateObject("Chilkat.CkDateTime")
bLocalTime = 1

set dt = CreateObject("Chilkat.DtObj")
i = 0
numItems = json.SizeOfArray("data")
Do While i < numItems
    json.I = i
    outFile.WriteLine("--- " & i)
    name = json.StringOf("data[i].name")
    If (json.LastMethodSuccess = 1) Then
        outFile.WriteLine("name: " & name)
    End If

    outFile.WriteLine("id: " & json.StringOf("data[i].id"))

    ' We can load the created_time into a CkDateTime...
    success = dtime.SetFromTimestamp(json.StringOf("data[i].created_time"))
    dtime.ToDtObj bLocalTime,dt

    outFile.WriteLine(dt.Month & "/" & dt.Day & "/" & dt.Year & "  " & dt.Hour & ":" & dt.Minute)
    i = i + 1
Loop

' We can get the paging information as follows:
outFile.WriteLine("URL for next page: " & json.StringOf("paging.next"))
outFile.WriteLine("before cursor: " & json.StringOf("paging.cursors.before"))
outFile.WriteLine("after cursor: " & json.StringOf("paging.cursors.after"))

' This is a sample JSON response:
' { 
'   "data": [
'     {
'       "created_time": "2016-09-29T20:46:18+0000",
'       "name": "Ignore my posts -- I'm doing some testing for Facebook related programming...",
'       "id": "10210199026347451"
'     },
'     { 
'       "created_time": "2016-09-19T02:00:42+0000",
'       "id": "10210091531240138"
'     },
'     { 
'       "created_time": "2016-09-19T02:00:42+0000",
'       "id": "10210091520620125"
'     },
'     { 
'       "created_time": "2016-09-19T01:59:46+0000",
'       "name": "I would've went for a swim had it not been for the sign",
'       "id": "10210091522299917"
'     },
'     { 
'       "created_time": "2016-09-12T00:37:35+0000",
'       "id": "10210023316834798"
'     }
'   ],
'   "paging": { 
'     "cursors": { 
'       "before": "MTAyMTAxOTkwMjYzNDc0NTEZD",
'       "after": "MTAyMTAwMjMzMTU4MzQ3OTgZD"
'     },
'     "next": "https:\/\/graph.facebook.com\/v2.7\/10224048320139890\/photos?type=uploaded&limit=5&after=MTAyMTAwMjMzMTU4MzQ3OTgZD"
'   }
' }
' 

outFile.Close