(VBScript) Extract SignatureValue from Signed XML

See more XML Digital Signatures Examples

Demonstrates how to extract the signature value from signed XML.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example will work with the following signed XML, which as been reformatted for readability.

' <?xml version="1.0" encoding="utf-8"?>
' <SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
'     <SOAP-ENV:Header>
'         <wsse:Security xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd" SOAP-ENV:mustUnderstand="1">
'             <ds:Signature xmlns:ds="http://www.w3.org/2000/09/xmldsig#">
'                 <ds:SignedInfo>
'                     <ds:CanonicalizationMethod Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#">
'                         <InclusiveNamespaces xmlns="http://www.w3.org/2001/10/xml-exc-c14n#" PrefixList="wsse SOAP-ENV"/>
'                     </ds:CanonicalizationMethod>
'                     <ds:SignatureMethod Algorithm="http://www.w3.org/2001/04/xmldsig-more#rsa-sha256"/>
'                     <ds:Reference URI="#Body">
'                         <ds:Transforms>
'                             <ds:Transform Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/>
'                         </ds:Transforms>
'                         <ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/>
'                         <ds:DigestValue>OwgHPZNfDkXnZsjpfzXqAcT3RV3HzmTsEy2bP44FJ0M=</ds:DigestValue>
'                     </ds:Reference>
'                 </ds:SignedInfo>
'                 <ds:SignatureValue>C+7FWngU....DJFBcdg==</ds:SignatureValue>
'                 <ds:KeyInfo>
'                     <ds:KeyValue>
'                         <ds:RSAKeyValue>
'                             <ds:Modulus>sXeRhM55P13.....NAcibRw==</ds:Modulus>
'                             <ds:Exponent>AQAB</ds:Exponent>
'                         </ds:RSAKeyValue>
'                     </ds:KeyValue>
'                 </ds:KeyInfo>
'             </ds:Signature>
'         </wsse:Security>
'     </SOAP-ENV:Header>
'     <SOAP-ENV:Body xmlns:SOAP-SEC="http://schemas.xmlsoap.org/soap/security/2000-12" SOAP-SEC:id="Body">
'         <z:FooBar xmlns:z="http://example.com"/>
'     </SOAP-ENV:Body>
' </SOAP-ENV:Envelope>

' -----------------------------------------------------------------------------------------
' There are a number of ways we can get the contents of the  <ds:SignatureValue>...</ds:SignatureValue>

filePath = "qa_data/xml_dsig_testing/sample_to_show_how_to_extract_sig.xml"

' If you know there will only be a single SignatureValue in the XML, you don't need to parse XML.
' Just do quick and simple string search..
' For example:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
success = sb.LoadFile(filePath,"utf-8")
If (success = 0) Then
    outFile.WriteLine("Failed to load file.")
    WScript.Quit
End If

base64Sig = sb.GetBetween("SignatureValue>","</")
outFile.WriteLine("base64Sig = " & base64Sig)

' -----------------------------------------------------------------------------------------
' If the XML might contain multiple signatures, but the signatures will always be located in the 
' same place, then you can (beforehand) copy a sample signed XML into Chilkat's online tool
' at Generate Parsing Code from XML
' to get the path to the SignatureValue.  For example, the line of code generated for the SignatureValue
' for the above XML is:
' string ds_SignatureValue = xml.GetChildContent("SOAP-ENV:Header|wsse:Security|ds:Signature|ds:SignatureValue");

' So you can simply use that path..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXmlFile(filePath)
' Assume success..

base64Sig = xml.GetChildContent("SOAP-ENV:Header|wsse:Security|ds:Signature|ds:SignatureValue")
outFile.WriteLine("base64Sig = " & base64Sig)

' -----------------------------------------------------------------------------------------
' Or perhaps you don't know where the signature is located in the XML.
' You can search for the tag..
' xSigVal is a Chilkat.Xml
Set xSigVal = xml.SearchForTag(xml,"*:SignatureValue")
If (xml.LastMethodSuccess = 1) Then
    outFile.WriteLine("base64Sig = " & xSigVal.Content)

Else
    outFile.WriteLine("No SignatureValue found.")
End If


outFile.Close