VBScript

Get E-way Bill System Access Token

See more HTTP Misc Examples

Sends a request to get an E-way bill system access token. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the public key provided by the E-way bill System
set pubkey = CreateObject("Chilkat.PublicKey")
success = pubkey.LoadFromFile("qa_data/pem/eway_publickey.pem")
If (success = 0) Then
    outFile.WriteLine(pubkey.LastErrorText)
    WScript.Quit
End If

' Encrypt the password using the RSA public key provided by eway..
password = "my_wepgst_password"
set rsa = CreateObject("Chilkat.Rsa")
rsa.Charset = "utf-8"
rsa.EncodingMode = "base64"

success = rsa.UsePublicKey(pubkey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Returns the encrypted password as base64 (because the EncodingMode = "base64")
encPassword = rsa.EncryptStringENC(password,0)
If (rsa.LastMethodSuccess = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Generate a random app_key.  This should be 32 bytes (us-ascii chars)
' We need 32 bytes because we'll be doing 256-bit AES ECB encryption, and 32 bytes = 256 bits.
set prng = CreateObject("Chilkat.Prng")
' Generate a random string containing some numbers, uppercase, and lowercase.
app_key = prng.RandomString(32,1,1,1)

outFile.WriteLine("app_key = " & app_key)

' RSA encrypt the app_key.
encAppKey = rsa.EncryptStringENC(app_key,0)
If (rsa.LastMethodSuccess = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Prepare the JSON body for the HTTP POST that gets the access token.
set jsonBody = CreateObject("Chilkat.JsonObject")
success = jsonBody.UpdateString("action","ACCESSTOKEN")
' Use your username instead of "09ABDC24212B1FK".
success = jsonBody.UpdateString("username","09ABDC24212B1FK")
success = jsonBody.UpdateString("password",encPassword)
success = jsonBody.UpdateString("app_key",encAppKey)

set http = CreateObject("Chilkat.Http")

' Add required headers.
' Use your ewb-user-id instead of "03AEXPR16A9M010"
http.SetRequestHeader "ewb-user-id","03AEXPR16A9M010"
' The Gstin should be the same as the username in the jsonBody above.
http.SetRequestHeader "Gstin","09ABDC24212B1FK"
http.Accept = "application/json"

' POST the JSON...
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","http://ewb.wepgst.com/api/Authenticate",jsonBody,"application/json",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

respStatusCode = resp.StatusCode
outFile.WriteLine("response status code =" & respStatusCode)
outFile.WriteLine("response body:")
outFile.WriteLine(resp.BodyStr)

If (respStatusCode <> 200) Then
    outFile.WriteLine("Failed in some unknown way.")
    WScript.Quit
End If

' When the response status code = 200, we'll have either
' success response like this:
'  {"status":"1","authtoken":"...","sek":"..."}
' 
' or a failed response like this:
' 
' {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}

' Load the response body into a JSON object.
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(resp.BodyStr)

status = json.IntOf("status")
outFile.WriteLine("status = " & status)

If (status <> 1) Then
    ' Failed.  Base64 decode the error
    ' {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}
    ' For an invalid password, the error is: {"errorCodes":"108"}
    set sbError = CreateObject("Chilkat.StringBuilder")
    success = json.StringOfSb("error",sbError)
    success = sbError.Decode("base64","utf-8")
    outFile.WriteLine("error: " & sbError.GetAsString())
    WScript.Quit
End If

' At this point, we know the request was entirely successful.
authToken = json.StringOf("authtoken")

' Decrypt the sek key using our app_key.
set crypt = CreateObject("Chilkat.Crypt2")
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "ecb"
crypt.KeyLength = 256
crypt.SetEncodedKey app_key,"us-ascii"
crypt.EncodingMode = "base64"

set bdSek = CreateObject("Chilkat.BinData")
success = bdSek.AppendEncoded(json.StringOf("sek"),"base64")
success = crypt.DecryptBd(bdSek)

' bdSek now contains the decrypted symmetric encryption key...
' We'll use it to encrypt the JSON payloads we send.

' Let's persist our authtoken and decrypted sek (symmetric encryption key).
' To send EWAY requests (such as to create an e-way bill), we'll just load 
' and use these pre-obtained credentials.
set jsonEwayAuth = CreateObject("Chilkat.JsonObject")
success = jsonEwayAuth.UpdateString("authToken",authToken)
success = jsonEwayAuth.UpdateString("decryptedSek",bdSek.GetEncoded("base64"))
jsonEwayAuth.EmitCompact = 0

set fac = CreateObject("Chilkat.FileAccess")
success = fac.WriteEntireTextFile("qa_data/tokens/ewayAuth.json",jsonEwayAuth.Emit(),"utf-8",0)

outFile.WriteLine("Saved:")
outFile.WriteLine(jsonEwayAuth.Emit())

' Sample output:
' {
'   "authToken": "IBTeFtxNfVurg71LTzZ2r0xK7",
'   "decryptedSek": "5g1TyTie7yoslU3DrbYATa7mWyPazlODE7cEh5Vy4Ho="
' 

outFile.Close