(VBScript) ETrade Revoke Access Token

Revokes an ETrade OAuth access token.

For more information, see https://apisb.etrade.com/docs/api/authorization/revoke_access_token.html

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

http.OAuth1 = 1
http.OAuthVerifier = ""
http.OAuthConsumerKey = "ETRADE_CONSUMER_KEY"
http.OAuthConsumerSecret = "ETRADE_CONSUMER_SECRET"

' Load the access token previously obtained via the OAuth1 Authorization
' This is the token that will be revoked.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/etrade.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load OAuth1 token")
    WScript.Quit
End If

http.OAuthToken = jsonToken.StringOf("oauth_token")
http.OAuthTokenSecret = jsonToken.StringOf("oauth_token_secret")

' resp is a Chilkat.HttpResponse
Set resp = http.QuickGetObj("https://api.etrade.com/oauth/revoke_access_token")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Make sure a successful response was received.
If (resp.StatusCode <> 200) Then
    outFile.WriteLine(resp.StatusLine)
    outFile.WriteLine(resp.Header)
    outFile.WriteLine(resp.BodyStr)
    WScript.Quit
End If

' If successful, the resp.BodyStr contains something like this: Revoked Access Token 
outFile.WriteLine(resp.BodyStr)

outFile.WriteLine("Success.")

outFile.Close