(VBScript) ETrade Renew Access Token

Renews an ETrade OAuth access token.

For more information, see https://apisb.etrade.com/docs/api/authorization/renew_access_token.html

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

http.OAuth1 = 1
http.OAuthVerifier = ""
http.OAuthConsumerKey = "ETRADE_CONSUMER_KEY"
http.OAuthConsumerSecret = "ETRADE_CONSUMER_SECRET"

' Load the access token previously obtained via the OAuth1 Authorization
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/etrade.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load OAuth1 token")
    WScript.Quit
End If

http.OAuthToken = jsonToken.StringOf("oauth_token")
http.OAuthTokenSecret = jsonToken.StringOf("oauth_token_secret")

' resp is a Chilkat.HttpResponse
Set resp = http.QuickGetObj("https://api.etrade.com/oauth/renew_access_token")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Make sure a successful response was received.
If (resp.StatusCode <> 200) Then
    outFile.WriteLine(resp.StatusLine)
    outFile.WriteLine(resp.Header)
    outFile.WriteLine(resp.BodyStr)
    WScript.Quit
End If

' If successful, the resp.BodyStr contains something like this:
' oauth_token=%3TiQRgQCRGPo7Xdk6G8QDSEzX0Jsy6sKNcULcDavAGgU%3D&oauth_token_secret=%7RrC9scEpzcwSEMy4vE7nodSzPLqfRINnTNY4voczyFM%3D
outFile.WriteLine(resp.BodyStr)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbRespBody = CreateObject("Chilkat.StringBuilder")
success = resp.GetBodySb(sbRespBody)
If (sbRespBody.ContentsEqual("Access Token has been renewed",0)) Then
    ' The documentation at https://apisb.etrade.com/docs/api/authorization/renew_access_token.html
    ' indicates that the response should be as described above.  However, the response received when
    ' trying to refresh a non-expired token was "Access Token has been renewed"
    outFile.WriteLine("Keeping the same access token, but it's renewed...")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Hashtable")
set hashTab = CreateObject("Chilkat.Hashtable")
success = hashTab.AddQueryParams(resp.BodyStr)

accessToken = hashTab.LookupStr("oauth_token")
accessTokenSecret = hashTab.LookupStr("oauth_token_secret")

' The access token + secret is what should be saved and used for
' subsequent REST API calls.
outFile.WriteLine("Access Token = " & accessToken)
outFile.WriteLine("Access Token Secret = " & accessTokenSecret)

' Save this access token for future calls.
' Just in case we need user_id and screen_name, save those also..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.AppendString("oauth_token",accessToken)
success = json.AppendString("oauth_token_secret",accessTokenSecret)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
success = fac.WriteEntireTextFile("qa_data/tokens/etrade.json",json.Emit(),"utf-8",0)

outFile.WriteLine("Success.")

outFile.Close