(VBScript) Encrypt / Decrypt Secure Strings

Demonstrates how to use the EncryptSecureENC and DecryptSecureENC methods to encrypt/decrypt secure strings. These methods were added in Chilkat v9.5.0.71 (released January 2018).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat Crypt API to have been previously unlocked.
' See Unlock Chilkat Crypt for sample code.

' Load the secure string with some text.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SecureString")
set secStr1 = CreateObject("Chilkat.SecureString")
success = secStr1.LoadFile("qa_data/txt/helloWorld.txt","utf-8")
If (success <> 1) Then
    outFile.WriteLine("Failed to load helloWorld.txt")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128
crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"
crypt.EncodingMode = "base64"

' Return the base64 encoded encrypted contents of secStr1.
encryptedStr = crypt.EncryptSecureENC(secStr1)
outFile.WriteLine("Encrypted string: " & encryptedStr)

' Output:
' Encrypted string: qiq+IFhcjTkEIkZyf31V/g==

' Decrypt to secStr2:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SecureString")
set secStr2 = CreateObject("Chilkat.SecureString")
success = crypt.DecryptSecureENC(encryptedStr,secStr2)

' Access the contents of secStr2
outFile.WriteLine("Decrypted string: " & secStr2.Access())

' Output:
' Decrypted string: Hello World!

outFile.Close