(VBScript) Encrypt File in Chunks using AES CBC

Demonstrates how to use the FirstChunk/LastChunk properties to encrypt a file chunk-by-chunk.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

fileToEncrypt = "qa_data/hamlet.xml"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set facIn = CreateObject("Chilkat.FileAccess")
success = facIn.OpenForRead(fileToEncrypt)
If (success <> 1) Then
    outFile.WriteLine("Failed to open file that is to be encrytped.")
    WScript.Quit
End If

outputEncryptedFile = "qa_output/hamlet.enc"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set facOutEnc = CreateObject("Chilkat.FileAccess")
success = facOutEnc.OpenForWrite(outputEncryptedFile)
If (success <> 1) Then
    outFile.WriteLine("Failed to encrypted output file.")
    WScript.Quit
End If

' Let's encrypt in 10000 byte chunks.
chunkSize = 10000
numChunks = facIn.GetNumBlocks(chunkSize)

crypt.FirstChunk = 1
crypt.LastChunk = 0

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")

i = 0
Do While i < numChunks
    i = i + 1
    If (i = numChunks) Then
        crypt.LastChunk = 1
    End If

    ' Read the next chunk from the file.
    ' The last chunk will be whatever amount remains in the file..
    success = bd.Clear()
    success = facIn.FileReadBd(chunkSize,bd)

    ' Encrypt.
    success = crypt.EncryptBd(bd)

    ' Write the encrypted chunk to the output file.
    success = facOutEnc.FileWriteBd(bd,0,0)

    crypt.FirstChunk = 0
Loop

' Make sure both FirstChunk and LastChunk are restored to 1 after
' encrypting or decrypting in chunks.  Otherwise subsequent encryptions/decryptions
' will produce unexpected results.
crypt.FirstChunk = 1
crypt.LastChunk = 1

facIn.FileClose 
facOutEnc.FileClose 

' Decrypt the encrypted output file in a single call using CBC mode:
decryptedFile = "qa_output/hamlet_dec.xml"
success = crypt.CkDecryptFile(outputEncryptedFile,decryptedFile)
' Assume success for the example..

' Compare the contents of the decrypted file with the original file:
bSame = facIn.FileContentsEqual(fileToEncrypt,decryptedFile)
outFile.WriteLine("bSame = " & bSame)

outFile.Close