(VBScript) Get the Email Received Date/Time

Get's the date/time from the topmost Received header. The date/time of when you received an email may be different than the date/time stored in the Date header field, which if truthful, is the date when the email was sent.

The Received header field will look something like this:

Received: from mail.example.com (mail.example.com [99.255.255.99])
 by inbound-smtp.us-west-2.amazonaws.com with SMTP id 72ma443vs1g0o6vqd8erojkpss35s0dt32h323o1
 for admin@chilkatsoft.com;
 Wed, 25 Jul 2018 08:04:23 +0000 (UTC)

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

success = email.LoadEml("qa_data/eml/p.eml")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = CreateObject("Chilkat.StringBuilder")
success = sb.Append(email.GetHeaderField("Received"))

' Replace semicolons with CRLF's
numReplaced = sb.Replace(";",vbCrLf)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringTable")
set st = CreateObject("Chilkat.StringTable")
success = st.AppendFromSb(sb)

If (st.Count = 0) Then
    outFile.WriteLine("Should have at least one line..")
    WScript.Quit
End If

' The date/time string is the last line in the string table.
success = sb.SetString(st.StringAt(st.Count - 1))
success = sb.Trim()

outFile.WriteLine("Received date/time = " & sb.GetAsString())

outFile.Close