VBScript

Load Signed and/or Encrypted Email and Unwrap Security Layers

See more Email Object Examples

The LoadEml method loads an email (.eml file containing the MIME of an email) and automatically unwraps the digital signature and encryption security layers. A program can then examine the properties of the email object to see what was unwrapped. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set email = CreateObject("Chilkat.Email")

' Provide PFX/.p12 files for any certs+keys needed for decryption.
' Signature verification does not need anything extra.  
' (Also, Chilkat will automatically find and use pre-installed certs + private keys needed for decryption
' on a Windows system.)
success = email.AddPfxSourceFile("/pfxFiles/certs_and_keys_1.pfx","pfxPassword1")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

success = email.AddPfxSourceFile("/pfxFiles/certs_and_keys_2.pfx","pfxPassword2")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

' ...

' Load a potentially signed and/or encrypted email.
success = email.LoadEml("someDir/someEmail.eml")

' If the email was signed and/or encrypted, it was "unwrapped", i.e.
' the email is already decrypted and in a state as if it were never signed or encrypted.

' You may check to see if the email was received encrypted or signed, and if so,
' whether it was successfully unwrapped and who signed or encrypted it:
If (email.ReceivedEncrypted = 1) Then

    outFile.WriteLine("This email was encrypted.")
    If (email.Decrypted = 1) Then
        outFile.WriteLine("This email was successfully decrypted.  It was encrypted by:")
        outFile.WriteLine(email.EncryptedBy)
    Else
        outFile.WriteLine("This email was not decrypted.")
    End If

End If

If (email.ReceivedSigned = 1) Then

    outFile.WriteLine("This email was signed.")
    If (email.SignaturesValid = 1) Then
        outFile.WriteLine("The signature was verified.  It was signed by:")
        outFile.WriteLine(email.SignedBy)
    Else
        outFile.WriteLine("The signature verification failed.")
    End If

End If

' At this point, the contents of the email, including attachments, can be accessed normally..

outFile.Close