(VBScript) Forward an Email using CreateForward

Reads an email from an IMAP server, creates a forward version of the email using the CreateForward method, and sends the email to another recipient.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Read the 1st (most recent) email in an Inbox.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.someMailServer.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

numEmails = imap.NumMessages

' Fetch the email at the last sequence number.
' (We are assuming the Inbox has at least 1 email)
' email is a Chilkat.Email
Set email = imap.FetchSingle(numEmails,0)
If (imap.LastMethodSuccess = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.WriteLine(email.Subject)

' eForward is a Chilkat.Email
Set eForward = email.CreateForward()

' The eForward email has no To or CC recipients yet.
' Add one or more..
success = eForward.AddTo("Chilkat Support","support@chilkatsoft.com")

' We also need to specify the From name/address.
eForward.FromAddress = "matt@someMailServer.com"
eForward.FromName = "Matt"

' If we wish to add text at the start of the email body:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbHtmlBody = CreateObject("Chilkat.StringBuilder")
If (eForward.HasHtmlBody() = 1) Then
    success = sbHtmlBody.Append(eForward.GetHtmlBody())
    success = sbHtmlBody.Prepend("<p>Hello, this is an email I'm forwarding to you...</p>")
    eForward.SetHtmlBody sbHtmlBody.GetAsString()
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPtBody = CreateObject("Chilkat.StringBuilder")
If (eForward.HasPlainTextBody() = 1) Then
    success = sbPtBody.Append(eForward.GetPlainTextBody())
    success = sbPtBody.Prepend("Hello, this is an email I'm forwarding to you..." & vbCrLf & vbCrLf)
    eForward.SetTextBody sbPtBody.GetAsString(),"text/plain"
End If

' We could save the .eml, then double-click on it to view in our mail program, such as Outlook or Thunderbird..
success = eForward.SaveEml("qa_output/forward.eml")

' We could send (forward) the email..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

mailman.SmtpHost = "smtp.someMailServer.com"
mailman.SmtpUsername = "myLogin"
mailman.SmtpPassword = "myPassword"
mailman.SmtpPort = 587
mailman.StartTLS = 1

success = mailman.SendEmail(eForward)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    outFile.WriteLine("Connection to SMTP server not closed cleanly.")
End If

outFile.WriteLine("Mail Sent!")


outFile.Close